[推薦]ASP編程通用函數(shù)收藏大全第1/2頁

更新時間：2007年08月08日 10:29:45 作者：

本帖將收集和征集最全面的ASP編程應用中通用功能函數(shù)，人人為我，我為人人：）
只要大家每人獻出一兩條自己收藏已久，精典的通用函數(shù)，我想本帖將會對許許多多的ASP編程愛好者、工作者有很大的幫助，也將成為大家ASP編程的必備函數(shù)集。
趕快檢查您自己的函數(shù)庫吧，看一下你有的我們這里都有了嗎？
如果你發(fā)現(xiàn)了你的函數(shù)庫里還有著那么一兩條鮮為人知的函數(shù)，那快點以下面格式跟帖回復吧。
發(fā)表通用函數(shù)帖子格式：

復制代碼代碼如下:

<% 
'****************************** 
'函數(shù)：Function RndIP(s) 
'參數(shù)：s，四個隨機生成的IP頭，如"218$211$61$221" 
'作者：阿里西西 
'日期：2007/7/12 
'描述：隨機IP地址生成，返回一個隨機IP地址值 
'示例：<%=RndIP("218$211$61$221")%> 
'****************************** 
Function RndIP(s) 
on error resume next 
Dim ip,ip1,ip2,ip3,a,b,c 
if s = "" or ubound(split(s,"$"))<>3 then 
response.write "IP前綴參數(shù)設(shè)置錯誤，請返回重新設(shè)置后啟動程序。" 
response.end 
end if 
Randomize 
ip1 = cInt(254*rnd) 
ip2 = cInt(254*rnd) 
ip3 = cInt(254*rnd) 
b = Int ((3*rnd)+1) 

a=Split(s,"$") 
c=a(b) 
RndIP = (c&"."&ip1&"."&ip2&"."&ip3) 
End Function 
%> 

過濾常用的非法字符

復制代碼代碼如下:

<%  
'******************************  
'函數(shù)：ReplaceBadChar(strChar)  
'參數(shù)：strChar，待過濾字符  
'作者：阿里西西  
'日期：2007/7/12  
'描述：過濾常用的非法字符  
'示例：<%=ReplaceBadChar("包含有非法字符的'*示例")%>  
'******************************  
function ReplaceBadChar(strChar)  
 if strChar="" then  
  ReplaceBadChar=""  
 else  
  ReplaceBadChar=replace(replace(replace(replace(replace(replace(replace(strChar,"'",""),"*",""),"?",""),"(",""),")",""),"<",""),".","")  
 end if  
end function  
%> 

格式化HTML字符顯示

復制代碼代碼如下:

<%  
'******************************  
'函數(shù)：HTMLEncode(fString)  
'參數(shù)：fString，待格式化字符串  
'作者：阿里西西  
'日期：2007/7/12  
'描述：格式化HTML字符顯示  
'示例：<%=HTMLEncode(fString)%>  
'******************************  
function HTMLEncode(fString)  
if not isnull(fString) then  
    fString = replace(fString, ">", "&gt;")  
    fString = replace(fString, "<", "&lt;")  
    fString = Replace(fString, CHR(32), "&nbsp;")  
    fString = Replace(fString, CHR(9), "&nbsp;")  
    fString = Replace(fString, CHR(34), "&quot;")  
    fString = Replace(fString, CHR(39), "&#39;")  
    fString = Replace(fString, CHR(13), "")  
    fString = Replace(fString, CHR(10) & CHR(10), "&nbsp; ")  
    fString = Replace(fString, CHR(10), "&nbsp; ")  
    HTMLEncode = fString  
end if  
end function  
%> 

生成不重復的隨機數(shù)，通常應用于靜態(tài)HTML生成的文件名

復制代碼代碼如下:

<%  
'******************************  
'函數(shù)：GetNewFileName  
'參數(shù)：無  
'作者：阿里西西  
'日期：2007/7/12  
'描述：生成不重復的隨機數(shù)，通常應用于靜態(tài)HTML生成的文件名  
'示例：<%=GetNewFileName()%>  
'******************************  
Function GetNewFileName()  
 dim ranNum  
 dim dtNow  
 dtNow=Now()  
 ranNum=int(90000*rnd)+10000  
 GetNewFileName=year(dtNow) & right("0" & month(dtNow),2) & right("0" & day(dtNow),2) & right("0" & hour(dtNow),2) & right("0" & minute(dtNow),2) & right("0" & second(dtNow),2) & ranNum  
End Function  
%> 

郵件地址驗證函數(shù)

復制代碼代碼如下:

<%  
'******************************  
'函數(shù)：IsValidEmail(email)  
'參數(shù)：email，待驗證的郵件地址  
'作者：阿里西西  
'日期：2007/7/12  
'描述：郵件地址驗證  
'示例：<%=IsValidEmail(alixixi@msn.com)%>  
'******************************  
function IsValidEmail(email)  
 dim names, name, i, c  
 IsValidEmail = true  
 names = Split(email, "@")  
 if UBound(names) <> 1 then  
    IsValidEmail = false  
    exit function  
 end if  
 for each name in names  
  if Len(name) <= 0 then  
   IsValidEmail = false  
      exit function  
  end if  
  for i = 1 to Len(name)  
      c = Lcase(Mid(name, i, 1))  
   if InStr("abcdefghijklmnopqrstuvwxyz_-.", c) <= 0 and not IsNumeric(c) then  
         IsValidEmail = false  
         exit function  
       end if  
    next  
    if Left(name, 1) = "." or Right(name, 1) = "." then  
       IsValidEmail = false  
       exit function  
    end if  
 next  
 if InStr(names(1), ".") <= 0 then  
  IsValidEmail = false  
    exit function  
 end if  
 i = Len(names(1)) - InStrRev(names(1), ".")  
 if i <> 2 and i <> 3 then  
    IsValidEmail = false  
    exit function  
 end if  
 if InStr(email, "..") > 0 then  
    IsValidEmail = false  
 end if  
end function  
%>