<%
'===================================================================
'XDOWNPAGE   ASP版本
'版本   1.00
'Code by  zykj2000
'Email:   zykj_2000@163.net
'BBS:   http://bbs.513soft.net
'本程序可以免費(fèi)使用、修改，希望我的程序能為您的工作帶來(lái)方便
'但請(qǐng)保留以上請(qǐng)息
'
'程序特點(diǎn)
'本程序主要是對(duì)數(shù)據(jù)分頁(yè)的部分進(jìn)行了封裝，而數(shù)據(jù)顯示部份完全由用戶自定義，
'支持URL多個(gè)參數(shù)
'
'使用說(shuō)明
'程序參數(shù)說(shuō)明
'PapgeSize      定義分頁(yè)每一頁(yè)的記錄數(shù)
'GetRS       返回經(jīng)過(guò)分頁(yè)的Recordset此屬性只讀
'GetConn      得到數(shù)據(jù)庫(kù)連接
'GetSQL       得到查詢語(yǔ)句
'程序方法說(shuō)明
'ShowPage      顯示分頁(yè)導(dǎo)航條,唯一的公用方法
'
'===================================================================

Const Btn_First="<font face=""webdings"">9</font>"  '定義第一頁(yè)按鈕顯示樣式
Const Btn_Prev="<font face=""webdings"">3</font>"  '定義前一頁(yè)按鈕顯示樣式
Const Btn_Next="<font face=""webdings"">4</font>"  '定義下一頁(yè)按鈕顯示樣式
Const Btn_Last="<font face=""webdings"">:</font>"  '定義最后一頁(yè)按鈕顯示樣式
Const XD_Align="Center"     '定義分頁(yè)信息對(duì)齊方式
Const XD_Width="100%"     '定義分頁(yè)信息框大小

Class Xdownpage
Private XD_PageCount,XD_Conn,XD_Rs,XD_SQL,XD_PageSize,Str_errors,int_curpage,str_URL,int_totalPage,int_totalRecord,XD_sURL


'=================================================================
'PageSize 屬性
'設(shè)置每一頁(yè)的分頁(yè)大小
'=================================================================
Public Property Let PageSize(int_PageSize)
 If IsNumeric(Int_Pagesize) Then
  XD_PageSize=CLng(int_PageSize)
 Else
  str_error=str_error & "PageSize的參數(shù)不正確"
  ShowError()
 End If
End Property
Public Property Get PageSize
 If XD_PageSize="" or (not(IsNumeric(XD_PageSize))) Then
  PageSize=10     
 Else
  PageSize=XD_PageSize
 End If
End Property

'=================================================================
'GetRS 屬性
'返回分頁(yè)后的記錄集
'=================================================================
Public Property Get GetRs()
 Set XD_Rs=Server.createobject("adodb.recordset")
 XD_Rs.PageSize=PageSize
 XD_Rs.Open XD_SQL,XD_Conn,1,1
 If not(XD_Rs.eof and XD_RS.BOF) Then
  If int_curpage>XD_RS.PageCount Then
   int_curpage=XD_RS.PageCount
  End If
  XD_Rs.AbsolutePage=int_curpage
 End If
 Set GetRs=XD_RS
End Property

'================================================================
'GetConn  得到數(shù)據(jù)庫(kù)連接
'
'================================================================ 
Public Property Let GetConn(obj_Conn)
 Set XD_Conn=obj_Conn
End Property

'================================================================
'GetSQL   得到查詢語(yǔ)句
'
'================================================================
Public Property Let GetSQL(str_sql)
 XD_SQL=str_sql
End Property

 

'==================================================================
'Class_Initialize 類的初始化
'初始化當(dāng)前頁(yè)的值
'
'================================================================== 
Private Sub Class_Initialize
 '========================
 '設(shè)定一些參數(shù)的黙認(rèn)值
 '========================
 XD_PageSize=10  '設(shè)定分頁(yè)的默認(rèn)值為10
 '========================
 '獲取當(dāng)前面的值
 '========================
 If request("page")="" Then
  int_curpage=1
 ElseIf not(IsNumeric(request("page"))) Then
  int_curpage=1
 ElseIf CInt(Trim(request("page")))<1 Then
  int_curpage=1
 Else
  Int_curpage=CInt(Trim(request("page")))
 End If

End Sub

'====================================================================
'ShowPage  創(chuàng)建分頁(yè)導(dǎo)航條
'有首頁(yè)、前一頁(yè)、下一頁(yè)、末頁(yè)、還有數(shù)字導(dǎo)航
'
'====================================================================
Public Sub ShowPage()
 Dim str_tmp
 XD_sURL = GetUrl()
 int_totalRecord=XD_RS.RecordCount
 If int_totalRecord<=0 Then
  str_error=str_error & "總記錄數(shù)為零，請(qǐng)輸入數(shù)據(jù)"
  Call ShowError()
 End If
 If int_totalRecord="" then
     int_TotalPage=1
 Else
  If int_totalRecord mod PageSize =0 Then
   int_TotalPage = CLng(int_TotalRecord / XD_PageSize * -1)*-1
  Else
   int_TotalPage = CLng(int_TotalRecord / XD_PageSize * -1)*-1+1
  End If
 End If

 If Int_curpage>int_Totalpage Then
  int_curpage=int_TotalPage
 End If

 '==================================================================
 '顯示分頁(yè)信息，各個(gè)模塊根據(jù)自己要求更改顯求位置
 '==================================================================
 response.write ""
 str_tmp=ShowFirstPrv
 response.write str_tmp
 str_tmp=showNumBtn
 response.write str_tmp
 str_tmp=ShowNextLast
 response.write str_tmp
 str_tmp=ShowPageInfo
 response.write str_tmp

 response.write ""
End Sub

'====================================================================
'ShowFirstPrv  顯示首頁(yè)、前一頁(yè)
'
'
'====================================================================
Private Function ShowFirstPrv()
 Dim Str_tmp,int_prvpage
 If int_curpage=1 Then
  str_tmp=Btn_First&" "&Btn_Prev
 Else
  int_prvpage=int_curpage-1
  str_tmp="<a href="""&XD_sURL & "1" & """>" & Btn_First&"</a> <a href=""" & XD_sURL & CStr(int_prvpage) & """>" & Btn_Prev&"</a>"
 End If
 ShowFirstPrv=str_tmp
End Function

'====================================================================
'ShowNextLast  下一頁(yè)、末頁(yè)
'
'
'====================================================================
Private Function ShowNextLast()
 Dim str_tmp,int_Nextpage
 If Int_curpage>=int_totalpage Then
  str_tmp=Btn_Next & " " & Btn_Last
 Else
  Int_NextPage=int_curpage+1
  str_tmp="<a href=""" & XD_sURL & CStr(int_nextpage) & """>" & Btn_Next&"</a> <a href="""& XD_sURL & CStr(int_totalpage) & """>" &  Btn_Last&"</a>"
 End If
 ShowNextLast=str_tmp
End Function


'====================================================================
'ShowNumBtn  數(shù)字導(dǎo)航
'
'
'====================================================================
Private Function showNumBtn()
 Dim i,str_tmp
 For i=1 to int_totalpage
  str_tmp=str_tmp & "[<a href=""" & XD_sURL & CStr(i) & """>"&i&"</a>] "
 Next
 showNumBtn=str_tmp
End Function


'====================================================================
'ShowPageInfo  分頁(yè)信息
'更據(jù)要求自行修改
'
'====================================================================
Private Function ShowPageInfo()
 Dim str_tmp
 str_tmp="頁(yè)次:"&int_curpage&"/"&int_totalpage&"頁(yè) 共"&int_totalrecord&"條記錄 "&XD_PageSize&"條/每頁(yè)"
 ShowPageInfo=str_tmp
End Function
'==================================================================
'GetURL  得到當(dāng)前的URL
'更據(jù)URL參數(shù)不同，獲取不同的結(jié)果
'
'==================================================================
Private Function GetURL()
 Dim strurl,str_url,i,j,search_str,result_url
 search_str="page="

 strurl=Request.ServerVariables("URL")
 Strurl=split(strurl,"/")
 i=UBound(strurl,1)
 str_url=strurl(i)'得到當(dāng)前頁(yè)文件名

 str_params=Trim(Request.ServerVariables("QUERY_STRING"))
 If str_params="" Then
  result_url=str_url & "?page="
 Else
  If InstrRev(str_params,search_str)=0 Then
   result_url=str_url & "?" & str_params &"&page="
  Else
   j=InstrRev(str_params,search_str)-2
   If j=-1 Then
    result_url=str_url & "?page="
   Else
    str_params=Left(str_params,j)
    result_url=str_url & "?" & str_params &"&page="
   End If
  End If
 End If
 GetURL=result_url
End Function

'====================================================================
' 設(shè)置 Terminate 事件。
'
'====================================================================
Private Sub Class_Terminate  
 XD_RS.close
 Set XD_RS=nothing
End Sub
'====================================================================
'ShowError  錯(cuò)誤提示
'
'
'====================================================================
Private Sub ShowError()
 If str_Error <> "" Then
  Response.Write("" & str_Error & "")
  Response.End
 End If
End Sub
End class



'set conn = server.CreateObject("adodb.connection")
'conn.open "driver={microsoft access driver (*.mdb)};dbq=" & server.Mappath("/data/5iduohai.mdb")
'
''#############類調(diào)用樣例#################
''創(chuàng)建對(duì)象
'Set mypage=new xdownpage
''得到數(shù)據(jù)庫(kù)連接
'mypage.getconn=conn
''sql語(yǔ)句
'mypage.getsql="select * from [DH_Company] order by id asc"
''設(shè)置每一頁(yè)的記錄條數(shù)據(jù)為5條
'mypage.pagesize=5
''返回Recordset
'set rs=mypage.getrs()
'顯示分頁(yè)信息，這個(gè)方法可以，在set rs=mypage.getrs()以后,可在任意位置調(diào)用，可以調(diào)用多次

'
''顯示數(shù)據(jù)
'Response.Write("<br/>")
'for i=1 to mypage.pagesize
''這里就可以自定義顯示方式了
'    if not rs.eof then 
'        response.write rs(0) & "<br/>"
'        rs.movenext
'    else
'         exit for
'    end if
'next
'mypage.showpage()
%>

最新評(píng)論