.版本 2
.DLL命令 Sleep, , "kernel32.dll", "Sleep", 公開
  .參數 dwMilliseconds, 整數型

.版本 2
.程序集 接口程序集
.子程序 取網段, 文本型
.參數 IP地址, 文本型
返回 (取文本左邊 (IP地址, 倒找文本 (IP地址, “.”, , 假)))
.子程序 格式化尾數, 文本型
.參數 文本, 文本型
返回 (文本替換 (“000”, 4 － 取文本長度 (文本), 取文本長度 (文本), 文本))
.子程序 格式化IP, 文本型
.參數 IP地址, 文本型
返回 (取網段 (IP地址) ＋ 格式化尾數 (到文本 (取IP尾數 (IP地址))))
.子程序 取IP尾數, 整數型
.參數 IP地址, 文本型
返回 (到整數 (取文本右邊 (IP地址, 取文本長度 (IP地址) － 取文本長度 (取網段 (IP地址)))))
.子程序 ipadd, 文本型
.參數 ip, 文本型
.局部變量 ip_arr_str, 文本型, , "4"
.局部變量 ip_arr_int, 整數型, , "4"
.局部變量 a, 整數型
ip_arr_str ＝ 分割文本 (ip, “.”, )
.計次循環(huán)首 (4, a)
  ip_arr_int [a] ＝ 到整數 (ip_arr_str [a])
.計次循環(huán)尾 ()
ip_arr_int [4] ＝ ip_arr_int [4] ＋ 1
.如果真 (ip_arr_int [4] ＞ 255)
  ip_arr_int [4] ＝ 0
  ip_arr_int [3] ＝ ip_arr_int [3] ＋ 1
.如果真結束
.如果真 (ip_arr_int [3] ＞ 255)
  ip_arr_int [3] ＝ 0
  ip_arr_int [2] ＝ ip_arr_int [2] ＋ 1
.如果真結束
.如果真 (ip_arr_int [2] ＞ 255)
  ip_arr_int [2] ＝ 0
  ip_arr_int [1] ＝ ip_arr_int [1] ＋ 1
.如果真結束
返回 (到文本 (ip_arr_int [1]) ＋ “.” ＋ 到文本 (ip_arr_int [2]) ＋ “.” ＋ 到文本 (ip_arr_int [3]) ＋ “.” ＋ 到文本 (ip_arr_int [4]))

.版本 2
.支持庫 EThread
.支持庫 sock
.支持庫 iext2
.支持庫 spec
.支持庫 eAPI
.支持庫 iext
.程序集 窗口程序集_啟動窗口
.程序集變量 網段, 文本型
.程序集變量 許可證, 整數型
.程序集變量 線程句柄
.程序集變量 超級列表框操作類, 超級列表框操作類
.程序集變量 列表框信息, 列表框信息, , "0"
.程序集變量 工作線程數, 整數型
.子程序 __啟動窗口_創(chuàng)建完畢
初始化 ()
許可證 ＝ 創(chuàng)建進入許可證 ()
.子程序 初始化
.局部變量 文本組, 文本型, , "0"
文本組 ＝ 取本機IP ()
.如果真 (取數組成員數 (文本組) ≥ 1)
  網段 ＝ 取網段 (文本組 [1])
  IP編輯框_開始.地址 ＝ 網段 ＋ “1”
  IP編輯框_結束.地址 ＝ 網段 ＋ “255”
.如果真結束
超級列表框操作類._初始化類 (超級列表框1.取窗口句柄 ())
.子程序 _按鈕_開始掃描_被單擊
啟動線程 (&掃描主線程, 到整數 (編輯框_線程數.內容), 線程句柄)
.子程序 掃描主線程
.參數 線程數, 整數型
.局部變量 bool, 邏輯型
.局部變量 startip, 文本型
.局部變量 stopip, 文本型
.局部變量 address, 整數型
清除數組 (列表框信息)
超級列表框操作類.數據_全部刪除 ()
startip ＝ IP編輯框_開始.地址
stopip ＝ IP編輯框_結束.地址
bool ＝ 真
.判斷循環(huán)首 (bool)
  .判斷循環(huán)首 (工作線程數 ≥ 線程數)
    Sleep (100)
  .判斷循環(huán)尾 ()
  address ＝ 申請內存 (15, )
  寫到內存 (startip, address, 15)
  啟動線程 (&掃描子線程, address, )
  工作線程數 ＝ 工作線程數 ＋ 1
  .如果 (startip ＝ stopip)
    跳出循環(huán) ()
  .否則
    startip ＝ ipadd (startip)
  .如果結束
.判斷循環(huán)尾 ()
.子程序 掃描子線程
.參數 參數, 整數型
.局部變量 time
.局部變量 ip, 文本型
.局部變量 局部_列表框信息, 列表框信息
重定義數組 (局部_列表框信息.列標題, 假, 3) ' 帶3個列
清除數組 (局部_列表框信息.列圖片索引) ' 不使用列圖標
ip ＝ 指針到文本 (參數)
time ＝ 通信測試 (ip, 到整數 (編輯框_延時.內容))
.判斷開始 (time ≠ -1)
  局部_列表框信息.圖片索引 ＝ 0
  局部_列表框信息.標題 ＝ 格式化IP (ip)
  局部_列表框信息.列標題 [1] ＝ 取遠程機器名 (ip)
  局部_列表框信息.列標題 [2] ＝ 取遠程網卡物理地址 (ip)
  局部_列表框信息.列標題 [3] ＝ 到文本 (time)
  進入許可區(qū) (許可證)
  狀態(tài)條1.置文本 (2, “存活主機數：” ＋ 到文本 (超級列表框1.取表項數 ()))
  加入成員 (列表框信息, 局部_列表框信息)
  超級列表框1.全部刪除 ()
  超級列表框操作類.數據_高速插入表項 (, 列表框信息, #排序方式_表項標題排序)
  數組清零 (局部_列表框信息.列標題)
  退出許可區(qū) (許可證)
.默認
.判斷結束
進入許可區(qū) (許可證)
工作線程數 ＝ 工作線程數 － 1
進度條1.位置 ＝ (到整數 (編輯框_線程數.內容) － 工作線程數) ÷ 到整數 (編輯框_線程數.內容) × 100
.判斷開始 (工作線程數 ＝ 0)
  狀態(tài)條1.置文本 (0, “準備就緒”)
  進度條1.位置 ＝ 0
.默認
  狀態(tài)條1.置文本 (0, “正在掃描...”)
.判斷結束
狀態(tài)條1.置文本 (1, “線程： ” ＋ 到文本 (工作線程數))
退出許可區(qū) (許可證)
釋放內存 (參數)
.子程序 __啟動窗口_將被銷毀
刪除進入許可證 (許可證)
關閉線程句柄 (線程句柄)
.子程序 _按鈕2_被單擊
關閉線程句柄 (線程句柄)
強制結束線程 (線程句柄)
.子程序 _按鈕_導出_被單擊
.局部變量 文本, 文本型
.局部變量 i, 整數型
文本 ＝ “IP地址” ＋ 取空白文本 (15) ＋ “主機名稱” ＋ 取空白文本 (15) ＋ “MAC地址” ＋ 取空白文本 (12) ＋ “延遲” ＋ #換行符
.計次循環(huán)首 (超級列表框1.取表項數 (), i)
  文本 ＝ 文本 ＋ 超級列表框1.取標題 (i － 1, 0) ＋ 取空白文本 (10) ＋ 超級列表框1.取標題 (i － 1, 1) ＋ 取空白文本 (10) ＋ 超級列表框1.取標題 (i － 1, 2) ＋ 取空白文本 (10) ＋ 超級列表框1.取標題 (i － 1, 3) ＋ #換行符
.計次循環(huán)尾 ()
.如果真 (通用對話框1.打開 ())
  .判斷開始 (寫到文件 (通用對話框1.文件名, 到字節(jié)集 (文本)))
    信息框 (“導出成功！”, 64, )
  .默認
    信息框 (“導出失??！”, 16, )
  .判斷結束
.如果真結束
.子程序 _編輯框_線程數_調節(jié)鈕被按下
.參數 按鈕值, 整數型
編輯框_線程數.內容 ＝ 到文本 (到整數 (編輯框_線程數.內容) ＋ 按鈕值)
.子程序 _編輯框_線程數_內容被改變
.判斷開始 (到整數 (編輯框_線程數.內容) ≤ 0)
  編輯框_線程數.內容 ＝ “100”
  信息框 (“數值必須大于0”, 48, )
.判斷 (到整數 (編輯框_線程數.內容) ＞ 1024)
  編輯框_線程數.內容 ＝ “100”
  信息框 (“數值小于1024”, 48, )
.默認
.判斷結束