快捷導(dǎo)航

SQL SERVER中SELECT和SET賦值相同點與不同點(推薦)

更新時間：2019年12月02日 09:27:04 作者：markkang

SELECT和SET在SQL SERVER中都可以用來對變量進(jìn)行賦值，但其用法和效果在一些細(xì)節(jié)上有些不同。今天小編給大家分享SQL SERVER中SELECT和SET賦值相同點與不同點，感興趣的朋友一起看看吧

SELECT和SET在SQL SERVER中都可以用來對變量進(jìn)行賦值，但其用法和效果在一些細(xì)節(jié)上有些不同。

1. 在對變量賦值方面，SET是ANSI標(biāo)準(zhǔn)的賦值方式，SELECT則不是。這也是SET方式被推薦使用的原因之一。

2. SELECT可以一次對多個變量進(jìn)行賦值，而SET一次只能對一個變量賦值。

DECLARE @NAME NVARCHAR(128), @AGE INT;
SET @NAME = N'小明';
SET @AGE=18;
PRINT @NAME;
PRINT @AGE;
GO
DECLARE @NAME NVARCHAR(128), @AGE INT;
SELECT @NAME = N'小明',@AGE=18;
PRINT @NAME;
PRINT @AGE;

3.當(dāng)使用子查詢給變量賦值時，則要求子查詢必須是標(biāo)量子查詢（即子查詢得到結(jié)果是一個數(shù)據(jù)或者一行一列），不能返回多個值，否則會報錯。

1）但要注意的是，如果在SELECT查詢語句中給變量賦值的時候，查詢語句返回記錄的多少都不會產(chǎn)生錯誤，變量所得的值是查詢語句最后一行的記錄的相應(yīng)值。

2）如果查詢結(jié)果沒有返回記錄，也就是說返回為NULL值時，將整個子查詢進(jìn)行賦值的方式，SET和SELECT都會設(shè)置為NULL，而在SELECT查詢語句中賦值，變量會保持為初始值不受影響。

IF (OBJECT_ID('tempdb..#temp') is not null)
BEGIN
  DROP TABLE #temp;
END
ELSE
BEGIN
  CREATE TABLE #temp(
  [Name] NVARCHAR(128) ,
  AGE INT
  )
END
GO
INSERT INTO #temp([Name],AGE) VALUES(N'小明',18)
INSERT INTO #temp([Name],AGE) VALUES(N'小張',19)
INSERT INTO #temp([Name],AGE) VALUES(N'小王',17)
GO
DECLARE @NAME1 NVARCHAR(128), @AGE1 INT,@NAME2 NVARCHAR(128), @AGE2 INT;
SET @NAME1=(SELECT TOP 1 [NAME] FROM #temp);  --SET標(biāo)量在查詢賦值
SELECT @AGE1=(SELECT TOP 1 AGE FROM #temp);    --SELECT標(biāo)量在查詢賦值
SELECT @NAME2=[NAME],@AGE2=[AGE] FROM #temp;  --SELECT查詢語句中賦值
PRINT @NAME1; --正確運行,顯示結(jié)果：小明
PRINT @AGE1; --正確運行,顯示結(jié)果：18
PRINT @NAME2; --正確運行,顯示結(jié)果：小王
PRINT @AGE2; --正確運行,顯示結(jié)果：17

GO

DECLARE @NAME1 NVARCHAR(128), @AGE1 INT,@NAME2 NVARCHAR(128), @AGE2 INT;
SELECT @NAME1=N'初始名字',@AGE1=0,@NAME2=N'初始名字',@AGE2=0; --初始化各變量值
SET @NAME1=(SELECT TOP 1 [NAME] FROM #temp WHERE 1>1);  --SET標(biāo)量在查詢賦值
SELECT @AGE1=(SELECT TOP 1 AGE FROM #temp WHERE 1>1);    --SELECT標(biāo)量在查詢賦值
SELECT @NAME2=[NAME],@AGE2=[AGE] FROM #temp WHERE 1>1;  --SELECT查詢語句中賦值
PRINT @NAME1; --正確運行,實際值：NULL, 顯示結(jié)果：（空白）
PRINT @AGE1; --正確運行,實際值：NULL, 顯示結(jié)果：（空白）
PRINT @NAME2; --正確運行,實際和顯示值：初始名字
PRINT @AGE2; --正確運行,實際和顯示值：0
GO

那么我們該如何選擇使用哪種方式：

1. 因SET作為ANSI的標(biāo)準(zhǔn)，因此其是推薦用法。

2. 在不考慮標(biāo)準(zhǔn)的情況下，如果涉及到對多個變量賦值，為了少寫代碼或者獲取多個全局變量的值時，請考慮使用SELECT，一是因為簡便，二是一些全局變量會在在第二句執(zhí)行時值發(fā)生變化。

總結(jié)

以上所述是小編給大家介紹的SQL SERVER中SELECT和SET賦值相同點與不同點，希望對大家有所幫助，如果大家有任何疑問請給我留言，小編會及時回復(fù)大家的。在此也非常感謝大家對腳本之家網(wǎng)站的支持！
如果你覺得本文對你有幫助，歡迎轉(zhuǎn)載，煩請注明出處，謝謝！

您可能感興趣的文章: