經(jīng)常用asp的同行，可能會建議用set rs=conn.execute(sql)來代替set rs=server.createobject(“ADODB.recordset”):rs.open conn,sql,1,1。還有一些同行更提出了用set rs=conn.execute(sql):res=rs.getRows(100)來優(yōu)化ASP程序。其實在沒有做此實驗前，我也是很相信這種方法的。實際效果果真如此嗎？經(jīng)過一番測試，我發(fā)現(xiàn)結(jié)果遠非如此，set rs=server.createobject(“ADODB.recordset”)的方法比set rs=conn.execute的方法快4~5倍。這個結(jié)果您信嗎？不信，更我來一起做這個測試。

數(shù)據(jù)說明真相。首先創(chuàng)建一個多記錄的數(shù)據(jù)庫。

set conn=createobject("adodb.connection")
conn.open "provider=microsoft.jet.oledb.4.0;data source=E:\labs\miaoqiyuan.cn\g.mdb"
do while conn.execute("select count(id) from site")(0)<1000000
	conn.execute("insert into site(sitename,siteadmin,siteurl,sitekey) values('苗啟源','http://localhost/app_login/','http://www.miaoqiyuan.cn','e10adc3949ba59abbe56e057f20f883e')")
loop

經(jīng)過幾個小時的運行，我得到了一個有63萬多條記錄的數(shù)據(jù)庫。數(shù)據(jù)庫大小為99.7MB(測試數(shù)據(jù)庫下載地址rs-execute-test.rar)。

為了保證數(shù)據(jù)的真實性，我們用公共的頭部header.asp來保存數(shù)據(jù)庫連接字符串。footer.asp來保存運行時間。

運行環(huán)境，Windows 2003 Server SP2。IIS6.0，CPU E2200 2.2GHz，內(nèi)存2Gx2。硬盤300G SATA+80G ATA。

公共頭部:header.asp

<%
startTme=timer()
set conn=server.createobject("ADODB.connection")
conn.open "provider=microsoft.jet.oledb.4.0;data source="&server.mappath("g.mdb")
%>

公共底部:footer.asp

<hr />總共用時：< %=(timer()-startTme)*1000%>毫秒

測試方法：以三種方式，每頁100條記錄。同時讀取第6000頁到6099頁的記錄共一萬條，并測出運行時間。

test1.asp，采用set rs=server.createobject(“ADODB.recordset”)的方法。

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"頁<hr />"

	set rs=server.createobject("adodb.recordset")
	rs.open "select * from site",conn,1,1
	rs.pagesize=100
	rs.absolutepage=6000+k
	i=0
	do while not rs.eof and i<100
		i=i+1
		response.write rs("id")&":"&rs("sitename")&"<br />"&vbCrlf
		rs.movenext
	loop
	rs.close
	set rs=nothing

next
%>

test2.asp 采用set rs=conn.execute()的方法

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"頁<hr />"

	set rs=conn.execute("select * from site")
	rs.movefirst
	rs.move (6000+k)*100
	i=0
	do while not rs.eof and i<100
		i=i+1
		response.write rs("id")&":"&rs("sitename")&"<br />"&vbCrlf
		rs.movenext
	loop
	rs.close
	set rs=nothing

next
%>

至于getRows，這種方法只能算是返回結(jié)果的優(yōu)化，并不能算是一種方法。我們采用兩種返回結(jié)果的方式測試。test3.asp采用set rs=server.createobject(“ADODB.recordset”)的方法,test4.asp采用set rs=conn.execute(sql)的方法

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"頁<hr />"

	set rs=server.createobject("adodb.recordset")
	rs.open "select * from site",conn,1,1
	rs.pagesize=100
	rs.absolutepage=6000+k
	res=rs.getRows(100)
	rs.close
	set rs=nothing
	for i=0 to 99
		response.write res(0,i)&":"&res(1,i)&"<br />"&vbCrlf
	next

next
%>

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"頁<hr />"

	set rs=conn.execute("select * from site")
	rs.movefirst
	rs.move (6000+k)*100
	res=rs.getRows(100)
	rs.close
	set rs=nothing
	for i=0 to 99
		response.write res(0,i)&":"&res(1,i)&"<br />"&vbCrlf
	next

next
%>

下面是我的測試結(jié)果：

為什么會出現(xiàn)這種結(jié)果呢？set rs=conn.execute(sql),set rs=server.createobject(“ADODB.recordset”)為什么為相差這么多？對比一下test1.asp、test3.asp與test2.asp、test4.asp，除了返回結(jié)果的方式不同，還有一處就是rs.move。難道是這個原因？把test3.asp的代碼稍微修改一下。存為test5.asp。

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"頁<hr />"

	set rs=server.createobject("adodb.recordset")
	rs.open "select * from site",conn,1,1
	rs.movefirst
	rs.move (6000+k)*100
	res=rs.getRows(100)
	rs.close
	set rs=nothing
	for i=0 to 99
		response.write res(0,i)&":"&res(1,i)&"<br />"&vbCrlf
	next

next
%>

經(jīng)過測試，test5.asp能比test3.asp快0.1~0.2秒，如果讀取100條數(shù)據(jù)，這點差距可以忽略不計。

由此可見：set rs=conn.execute的方式確實比set rs=server.createobject(“ADODB.recordset”)方式慢，在學(xué)校的時候，老師教的一般都是set rs=server.createobject(“ADODB.recordset”)的方法，真正工作室，學(xué)習(xí)所謂的高手set rs=conn.execute優(yōu)化的方法，結(jié)果最終發(fā)現(xiàn)，而鄙視用老師教的方法寫程序的同行，最終發(fā)現(xiàn)還是老師教的速度快，而且set rs=server.createobject(“ADODB.recordset”)的方法比set rs=conn.execute的方法快4~5倍。囧。。。。

難道set rs=conn.execute就一無是處了嗎？在數(shù)據(jù)插入方面，兩者的差別有多大呢？

下面是其他網(wǎng)友的補充

沒有可比性，為什么非要比呢？
set rs=conn.execute()
rs.getrows()
這種方法一般用在數(shù)據(jù)量少的情況下，比如說只有幾十幾百條數(shù)據(jù)的情況下，它只讀一次數(shù)據(jù)庫，然后把結(jié)果存入一個二維數(shù)組中，在這之后的操作就不需要數(shù)據(jù)庫，而是直接對內(nèi)存中的數(shù)據(jù)進行操作了，速度絕對比用常規(guī)方法快，而且也節(jié)省資源。而用常規(guī)方法的話，數(shù)據(jù)庫操作得多少次？而在日常的情況下，一次讀取大量數(shù)據(jù)的情況是很少的，所以在很多地方都提到使用上面這種方法，就是緣于此。
還有上面比的分頁，常規(guī)方法由于它自身的局限，對數(shù)據(jù)庫的操作很費資源的，別說只是快那零點幾秒，好的程序到最后拼的就是那零點幾秒。

rs.open sql,conn 與conn.execute(sql)的區(qū)別

什么時候用什么?
那就憑個人經(jīng)驗積累的感覺了:
如果只需要一筆帶過的碰碰數(shù)據(jù)庫,用execute
如果要對數(shù)據(jù)庫作比較龐雜的操作!則最好用 rs.open

rs.open sql,conn：如果sql是delete,update,insert則會返回一個關(guān)閉的記錄集，在使用過程中不要來個rs.close在文件最后再寫rs.close中間可以來多個記錄集rs1.open sql1,conn，最后一塊關(guān)閉記錄集:rs.close rs1.close

conn.execute(sql)：如果sql是update,insert,delete則應(yīng)該使用conn.execute(sql)也可以不要括號conn.execute sql

如果sql是select語句則應(yīng)該使用set rs=conn.execute(sql)括號一定要，不能省略:這是因為vb的特性,帶返回值的調(diào)用必須加括號，不帶返回值的調(diào)用可以不要括號。

1.conn.execute

sql="select * from admin where username='xiaozhu'"
set rs=conn.execute(sql)
'執(zhí)行完以后自動關(guān)閉記錄集
'最后只需要關(guān)閉連接就可以了
conn.close
set conn=nothing

2.rs.open

set rs=server.createobject("adodb.recordset")
sql="select * from admin where username='xiaozhu'"
rs.open sql,conn,1,1
'可以自己設(shè)定一些參數(shù)，即鎖定和游標(biāo)的移動方式
'最后要關(guān)閉記錄集和連接
rs.close
set rs=nothing
conn.close
set conn=nothing

3.command.execute

sql="select * from admin where username='xiaozhu'"
set rs=command.execute(sql)

1.
set rs=conn.execute("如果是select語句") 得到的rs.recordcount=-1
rs.open sql,conn("sql為select語句") 得到的rs.recordcount為正常的記錄數(shù)

2.
rs.open是打開數(shù)據(jù)庫 conn.execute 是執(zhí)行SQL指令
set rs=conn.execute(insert,update,delete)返回一個關(guān)閉了的記錄集
set rs=conn.execute(select)返回一個沒有關(guān)閉的記錄集

 3.
CONN.EXECUTE(SQL,RowsAffected,C)

  參數(shù)含義:

  SQL的值可以是SQL語句、表名、存儲過程名，也可以是數(shù)據(jù)提供者所能接受的任意字符串。為了提高性能，最好為C參數(shù)指定合適的值

  可選參數(shù)RowsAffected將返回INSERT、UPDATE或DELETE查詢執(zhí)行以后所影響的數(shù)目。這些查詢會返回一個關(guān)閉的Recordset對象。

  一個SELECT查詢將返回RowsAffected值為-1并且返回帶有一行或多行內(nèi)容的打開的Recordset。

 4.
conn.execute sql適合于不需返回recordset對象時使用，比如下面的代碼：
sql="delete from enews where id="&cstr(id)
conn.execute sql

如果需要返回recordset對象，則使用如下代碼：
sql="select from enews where id="&cstr(id)
set rs = conn.execute(sql)

如果去掉execute(sql)這兒的括號(即為set rs = conn.execute sql)，就會提示“語句未結(jié)束”這樣的錯誤提示，我翻看了一下語法格式，發(fā)現(xiàn)有二種格式，詳解如下：

格式一：Connection對象名.Execute(SQL指令).
格式二：Connection對象名.Execute(數(shù)據(jù)表名)。
附：

set rs = conn.execute(sql) 
 
  是帶有返回值的，一般sql為查詢的時候使用。如 
  set rs = conn.execute("select * from ...") 
  當(dāng)然執(zhí)行insert into 和delete也是可以的 
  set rs = conn.execute("insert into table (f1,f2..") 
  但是要創(chuàng)建Recordset對象，占用服務(wù)器資源。在insert into, delete的時候我們一般不需要返回記錄集。所以我是這樣認為的： 
 
  在使用查詢的時候，用 set rs = conn.execute("select * from table") 
  在插入和刪除時候，用 conn.execute("delete from table where ...") 
 
  第二種方式代碼簡潔，不需要顯式地創(chuàng)建Recordset對象(但實際上好象是隱式創(chuàng)建的) 
 
  第二種方法還有一些簡潔的寫法：如，最某表的記錄數(shù) 
 
  dim count 
  count = conn.execute(select count(*) from table)(0) 
  上面的語句等于 
  count = conn.execute(select count(*) from table).fields(0).value 
 
  綜上：區(qū)別在于set rs = conn.execute是顯示創(chuàng)建recordset對象，而conn.execute是隱式的。 
  能用conn.execute的時候就用conn.execute，好處有 
  一、代碼簡潔 
  二、效率應(yīng)該有所提高

再摘引一下：（srnld（天涯））

形成記錄集的方法有三種 CONN.execute   rs.open   Command.execute 
  方法用法大大不通 
 
  通常 Set rs=CONN.execute(SQL) 
  或直接 rs=CONN.execute(SQL) 
 
  和   Set rs=Server.CreateObject("ADODB.Recordset") 
    rs.open SQL,CONN,0,1   或 rs.open SQL,CONN 
  這種情況 通常open比上一個性能要好那么一丁點 
  (   command對象更靈活,執(zhí)行范圍更廣) 
 
  使用 CONN.execute 可以不用關(guān)閉直接執(zhí)行下一個 set rs=conn.execute(SQL) 
  但性能速度會大打折扣!! 
  大約要慢 2~5倍!!(這是我在msSQL循環(huán)1000次親自測試過的,不信你馬上自己測試),所以執(zhí)行下一個 rs=conn.execute之前!!一定要關(guān)閉掉!是個好習(xí)慣! 
  使用單一對象的rs   rs.open在open下一個記錄集之前,必需要求顯示關(guān)閉,否則出錯,速度在SQL,CONN,0,1的情況下可前者基本一樣 
 
  所以我喜歡使用直設(shè)置一個 CreateObject("adodb.recordser")(在不需要多個記錄集交錯操作的情況下,多個也不礙是!) 
  然后從頭用到尾!!! 
  開門關(guān)門開門關(guān)門~~~~~咵踏咵踏~~~~ 
  最后一個 set rs=nothing 化上句號,爽! 
 
  更主要是 open提供非常靈活的操作數(shù)據(jù)庫元數(shù)據(jù)的非常多的屬性!! 
  打開百寶箱,金光燦燦什么都看見! 
  有很多情況下是非得用open來做的! 
  而conn.execute 想黑布下?lián)Q膠卷~~~偷偷摸摸~~非常單一!!! 
 
  比如: 
 
  rs1.open SQL1,conn,0,1 
  rs.open SQL,conn,1,3 
  if rs(0)<0 then rs(0)=0 
  rs(1)=aaa 
  rs(2)=bbb 
  rs.update ' 更新記錄集寫到數(shù)據(jù)庫 
 
  rs.addnew '加一條新記錄 
  rs(0)=1 
  rs(1)=ddd 
  rs(2)=kkk 
  rs.update 
  id=rs(3)   rs(s) '取的字段是自動編號 立即獲得新記錄的自動編號id //這是非常常用的 
 
  rs1.addnew 對rs1添加關(guān)連使用id rs的新記錄 
  rs1("id")=id 
  rs1(1)=... 
  .. 
  rs1.update 
 
  rs1.close:set rs1=nothing 
  rs.close:set rs=nothing 
 
 
  上面的操作如果采用CONN.execute 則要用到四個 CONN.execute 
 
  CONN.execute("update ..") 
  CONN.execute("insert into 表1:") 
  rs=CONN.execute("select 新的自動 id") 
  CONN.execute("insert into 表二") 
  那一種方法邏輯條理更好~~一目了然 
 
  ====================== 
 
  還有一個有趣的使用Recordset open記錄的方法!! 
  我想起來是有點費解 
 
  Set rs=server.CreateObject("Adodb.recordset") 
  Set rs=server.CreateObject("Adodb.recordset") 
 
  rs.open SQL1,CONN 
  rs.open SQL2,CONN 
 
  '嘿嘿~~~這是同時設(shè)置同名的兩個對象來打開兩個記錄集,而且是可用的! 
  '只要取的列名合乎這兩個記錄集中元數(shù)據(jù) 
  '則正常操作!! 
  擴展開來 
 
  Set rs=server.CreateObject("Adodb.recordset") 
  Set rs=server.CreateObject("Adodb.recordset") 
  Set rs=server.CreateObject("Adodb.recordset") 
  Set rs=server.CreateObject("Adodb.recordset") 
 
  rs.open SQL1,CONN 
  rs.open SQL2,CONN 
  rs.open SQL3,CONN 
  rs.open SQL4,CONN 
 
  這樣大于二個同名的 rs我還沒試過!! 
 
  感覺有點相當(dāng)與 SQL聯(lián)合查詢再打開記錄集~~~ 
  以前我這樣用過!!應(yīng)該不是眼花!!

到此這篇關(guān)于set rs=conn.execute,set rs=server.createobject(“ADODB.recordset”)的性能對比的文章就介紹到這了,更多相關(guān)conn.execute與ADODB.recordset的對比內(nèi)容請搜索腳本之家以前的文章或繼續(xù)瀏覽下面的相關(guān)文章希望大家以后多多支持腳本之家！

最新評論