在新電腦配置或者新人入職時需要對java開發(fā)相關(guān)環(huán)境進(jìn)行配置安裝，但時常會因為安裝配置不到位或者操作錯誤導(dǎo)致時間的浪費(fèi)，所以在空余時間收集了一系列軟件的免安裝版本，并且編寫了相關(guān)配置腳本，讓環(huán)境安裝變得標(biāo)準(zhǔn)化。

概覽

安裝包目錄如下如所示

BaseEnv包含jdk（1.8）,maven（3.2.5）

ProgramEnv包含idea（2019.2）

SoftEnv包含mysql（5.7），navicat（15），redis，redismanage（1.5.8）

remark為安裝總說明

setting.bat腳本配置環(huán)境變量

mysql.bat腳本安裝mysql服務(wù)

redis.bat腳本安裝redis服務(wù)

icon腳本在桌面創(chuàng)建軟件快捷方式

上述軟件可以基本滿足日常java開發(fā)的環(huán)境要求

安裝包百度網(wǎng)盤地址：

鏈接: https://pan.baidu.com/s/19WIgCkSgw7Sn71FDkWZRIw 提取碼: kbf6?

環(huán)境變量腳本

環(huán)境變量腳本可以通過wmic ENVIRONMENT語句進(jìn)行刪除重新重新創(chuàng)建，Path變量的變更可以通過get

VariableValue|findstr /i語句進(jìn)行判斷是否存在，bat腳本可以獲取當(dāng)前路徑動態(tài)的去進(jìn)行配置，免去了手動

輸入的繁瑣步驟，腳本如下

@echo off
color 02

:step1
cd /d %~dp0
set currentPath=%PATH%
set currentDir=%cd%
set javaPath=%currentDir%\BaseEnv\jdk
set mavenPath=%currentDir%\BaseEnv\maven
set mysqlPath=%currentDir%\SoftEnv\mysql
set redisPath=%currentDir%\SoftEnv\redis

:step2
wmic ENVIRONMENT where "name='JAVA_HOME'" delete
wmic ENVIRONMENT create name="JAVA_HOME",username="<system>",VariableValue="%javaPath%"
wmic ENVIRONMENT where "name='MAVEN_HOME'" delete
wmic ENVIRONMENT create name="MAVEN_HOME",username="<system>",VariableValue="%mavenPath%"
wmic ENVIRONMENT where "name='CLASSPATH'" delete
wmic ENVIRONMENT create name="CLASSPATH",username="<system>",VariableValue=".;%%JAVA_HOME%%\lib\toos.jar;%%JAVA_HOME%%\lib\dt.jar"
wmic ENVIRONMENT where "name='MYSQL_HOME'" delete
wmic ENVIRONMENT create name="MYSQL_HOME",username="<system>",VariableValue="%mysqlPath%"
wmic ENVIRONMENT where "name='REDIS_HOME'" delete
wmic ENVIRONMENT create name="REDIS_HOME",username="<system>",VariableValue="%redisPath%"

echo.
goto step3

:step3
wmic ENVIRONMENT where "name='Path'" get VariableValue|findstr /i /c:"%%JAVA_HOME%%\bin">nul&&(goto step5)  
echo PATH環(huán)境變量中未添加: %%JAVA_HOME%%\bin 
wmic ENVIRONMENT where "name='Path' and username='<system>'" set VariableValue="%currentPATH%;%%JAVA_HOME%%\bin"
set currentPATH=%currentPATH%;%%JAVA_HOME%%\bin
echo.

:step5
echo JAVA_HOME PATH中已添加
wmic ENVIRONMENT where "name='Path'" get VariableValue|findstr /i /c:"%%MAVEN_HOME%%\bin">nul&&(goto step6)  
echo PATH環(huán)境變量中未添加: %%MAVEN_HOME%%\bin 
wmic ENVIRONMENT where "name='Path' and username='<system>'" set VariableValue="%currentPATH%;%%MAVEN_HOME%%\bin"
set currentPATH=%currentPATH%;%%MAVEN_HOME%%\bin
echo.

:step6
echo MYSQL_HOME PATH中已添加
wmic ENVIRONMENT where "name='Path'" get VariableValue|findstr /i /c:"%%MYSQL_HOME%%\bin">nul&&(goto step7)  
echo PATH環(huán)境變量中未添加: %%MYSQL_HOME%%\bin 
wmic ENVIRONMENT where "name='Path' and username='<system>'" set VariableValue="%currentPATH%;%%MYSQL_HOME%%\bin"
set currentPATH=%currentPATH%;%%MYSQL_HOME%%\bin
echo.

:step7
echo MYSQL PATH中已添加
wmic ENVIRONMENT where "name='Path'" get VariableValue|findstr /i /c:"%%REDIS_HOME%%">nul&&(goto step8)  
echo PATH環(huán)境變量中未添加: %%REDIS_HOME%%
wmic ENVIRONMENT where "name='Path' and username='<system>'" set VariableValue="%currentPATH%;%%REDIS_HOME%%"
echo.

:step8
echo REDIS PATH中已添加

pause

服務(wù)安裝腳本

redis通過--service-install語句進(jìn)行windows服務(wù)的安裝

@echo off
color 02

"%cd%\SoftEnv\redis\redis-server.exe"  --service-install %cd%\SoftEnv\redis\redis.windows.conf 

net start Redis

pause

mysql通過--initialize-insecure語句進(jìn)行windows服務(wù)的安裝

@echo off
color 02

"%cd%\SoftEnv\mysql\bin\mysqld.exe" --install mysql --defaults-file="%cd%\SoftEnv\mysql\my.ini"
"%cd%\SoftEnv\mysql\bin\mysqld.exe" --initialize-insecure --user=mysql

net start mysql

pause

快捷方式創(chuàng)建腳本

通過WshShell腳本的方式進(jìn)行圖標(biāo)快捷方式的創(chuàng)建

@echo off
set currentDir=%cd%

set Program=%cd%\ProgramEnv\idea\bin\idea64.exe
set LnkName=idea
set WorkDir=
set Desc=idea
if not defined WorkDir call:GetWorkDir "%Program%"
(echo Set WshShell=CreateObject("WScript.Shell"^)
echo strDesKtop=WshShell.SpecialFolders("DesKtop"^)
echo Set oShellLink=WshShell.CreateShortcut(strDesKtop^&"\%LnkName%.lnk"^)
echo oShellLink.TargetPath="%Program%"
echo oShellLink.WorkingDirectory="%WorkDir%"
echo oShellLink.WindowStyle=1
echo oShellLink.Description="%Desc%"
echo oShellLink.Save)>makelnk.vbs
echo idea icon link set success！
makelnk.vbs

set Program=%cd%\SoftEnv\navicat\navicat.exe
set LnkName=navicat
set WorkDir=
set Desc=navicat
if not defined WorkDir call:GetWorkDir "%Program%"
(echo Set WshShell=CreateObject("WScript.Shell"^)
echo strDesKtop=WshShell.SpecialFolders("DesKtop"^)
echo Set oShellLink=WshShell.CreateShortcut(strDesKtop^&"\%LnkName%.lnk"^)
echo oShellLink.TargetPath="%Program%"
echo oShellLink.WorkingDirectory="%WorkDir%"
echo oShellLink.WindowStyle=1
echo oShellLink.Description="%Desc%"
echo oShellLink.Save)>makelnk.vbs
echo navicat icon link set success！
makelnk.vbs

set Program=%cd%\SoftEnv\redismanage\rdm.exe
set LnkName=rdm
set WorkDir=
set Desc=rdm
if not defined WorkDir call:GetWorkDir "%Program%"
(echo Set WshShell=CreateObject("WScript.Shell"^)
echo strDesKtop=WshShell.SpecialFolders("DesKtop"^)
echo Set oShellLink=WshShell.CreateShortcut(strDesKtop^&"\%LnkName%.lnk"^)
echo oShellLink.TargetPath="%Program%"
echo oShellLink.WorkingDirectory="%WorkDir%"
echo oShellLink.WindowStyle=1
echo oShellLink.Description="%Desc%"
echo oShellLink.Save)>makelnk.vbs
echo rdm icon link set success！
makelnk.vbs

del /f /q makelnk.vbs
exit
goto :eof
:GetWorkDir
set WorkDir=%~dp1
set WorkDir=%WorkDir:~,-1%
goto :eof

到此這篇關(guān)于bat腳本一鍵配置java開發(fā)環(huán)境的文章就介紹到這了,更多相關(guān)bat腳本一鍵配置java環(huán)境內(nèi)容請搜索腳本之家以前的文章或繼續(xù)瀏覽下面的相關(guān)文章希望大家以后多多支持腳本之家！

您可能感興趣的文章: