<%
class Cache
    private obj            'cache內(nèi)容
    private expireTime        '過期時(shí)間
    private expireTimeName    '過期時(shí)間application名
    private cacheName        'cache內(nèi)容application名
    private path            'url

    private sub class_initialize()
        path=request.servervariables("url")
        path=left(path,instrRev(path,"/"))
    end sub

    private sub class_terminate()
    end sub

    public property get blEmpty
        '是否為空
        if isempty(obj) then
            blEmpty=true
        else
            blEmpty=false
        end if
    end property

    public property get valid
        '是否可用(過期)
        if isempty(obj) or not isDate(expireTime) then
            valid=false
        elseif CDate(expireTime)<now then
                valid=false
        else
            valid=true
        end if
    end property

    public property let name(str)
        '設(shè)置cache名
        cacheName=str & path
        obj=application(cacheName)
        expireTimeName=str & "expires" & path
        expireTime=application(expireTimeName)
    end property

    public property let expires(tm)
        '重設(shè)置過期時(shí)間
        expireTime=tm
        application.lock
        application(expireTimeName)=expireTime
        application.unlock
    end property

    public sub add(var,expire)
        '賦值
        if isempty(var) or not isDate(expire) then
            exit sub
        end if
        obj=var
        expireTime=expire
        application.lock
        application(cacheName)=obj
        application(expireTimeName)=expireTime
        application.unlock
    end sub

    public property get value
        '取值
        if isempty(obj) or not isDate(expireTime) then
            value=null
        elseif CDate(expireTime)<now then
            value=null
        else
            value=obj
        end if
    end property

    public sub makeEmpty()
        '釋放application
        application.lock
        application(cacheName)=empty
        application(expireTimeName)=empty
        application.unlock
        obj=empty
        expireTime=empty
    end sub

    public function equal(var2)
        '比較
        if typename(obj)<>typename(var2) then
            equal=false
        elseif typename(obj)="Object" then
            if obj is var2 then
                equal=true
            else
                equal=false
            end if
        elseif typename(obj)="Variant()" then
            if join(obj,"^")=join(var2,"^") then
                equal=true
            else
                equal=false
            end if
        else
            if obj=var2 then
                equal=true
            else
                equal=false
            end if
        end if
    end function
end class
%>

    set myCache=new cache
    myCache.name="flash1"
    If myCache.valid then
        StartGet = myCache.value
    Else
        StartGet = GetHttpPage(HttpUrl)    
        myCache.add StartGet,dateadd("h",3,Now)
    End if 
    List=GetBody(StartGet,"</form>","<!-- ********網(wǎng)頁中部代碼結(jié)束******** -->",False,False)