獲取軟件下載的真實(shí)地址！再談獲取Response.redirect重定向的URL
http://www.im286.com/viewthread.php?tid=1550010&extra=page%3D1
其實(shí)這個問題落伍談了n次了
其中care4也說了兩次所以如果你有問題最好先搜索一下 說不定問題早有人解決了
http://www.im286.com/viewthread. ... ;highlight=%2Bcare4
http://www.im286.com/viewthread. ... ;highlight=%2Bcare4
care4的代碼有一個小缺點(diǎn) 就是需要組件。
第一個是.net組件 二不是 但用組件始終不太方便有沒有asp直接獲取的方式呢
答案是有的
我寫的一個vb簡單的winsock獲取的代碼
http://www.im286.com/viewthread. ... t=Response.redirect
當(dāng)時我說用asp好像不能獲得，那是當(dāng)時沒有去csdn混去，現(xiàn)在搞定了
首先我們要了解為什么xmlhttp組件無法獲得這樣的跳轉(zhuǎn)真實(shí)地址
用Response.Redirect跳轉(zhuǎn)，PHP里面是Header("Location",$URL);
這兩種方式都是一樣的原理，就是在輸出的HTTP頭里面加上一個Location字段
同時把返回的HTTP狀態(tài)值設(shè)為302，瀏覽器就會認(rèn)為當(dāng)前請求的頁面已經(jīng)
被移動到Location指定的路徑
那么為什么xmlhttp無法獲得呢？
原因很簡單
XMLHTTP組件在處理包含Location頭的302消息時太智能了，直接給跳轉(zhuǎn)到最后的頁面，也就是說～我們看不到中間的過程！比爾自作聰明阿 ！
不過還好MSXML4里面提供了一個可用的新的組件：WinHttp.WinHttpRequest.5.1，這個也是MSXML4 XMLHTTP組件的核心。 WinHttp.WinHttpRequest有一個十分關(guān)鍵的屬性：Option，這個屬性的第六個索引就是指示是否自動跳轉(zhuǎn)，然后就可以輕松的使用XMLHTTP組件的getResponseHeader和getAllResponseHeaders方法來獲取返回的HTTP頭信息了。
好接下來就看代碼了
Dim oHttp
Set oHttp=Server.CreateObject("WinHttp.WinHttpRequest.5.1"
oHttp.Option(6)=0 '禁止自動Redirect，最關(guān)鍵的 剩下的就簡單讀取數(shù)據(jù)都估計(jì)大家都會
oHttp.SetTimeouts 5000,5000,30000,5000 '設(shè)置超時～和ServerXMLHTTP組件一樣
oHttp.Open "GET",sUrl,False '以同步模式打開URL
If oHttp.Status<>200 And oHttp.Status<>302 Then
'oHttp.Status對應(yīng)返回的HTTP狀態(tài)，如果是200，表示這個就是最終頁面，沒有Location跳轉(zhuǎn)
'如果是302，表示當(dāng)前請求的URL已經(jīng)被移動，需要根據(jù)HTTP頭來跳轉(zhuǎn)
'對于其他數(shù)值的狀態(tài)，基本上我們不要處理，但是你要處理也可以比如 440或者別的狀態(tài)你自己處理就可以了！
Else
'在這里對返回的HTTP頭和文檔內(nèi)容進(jìn)行處理
End If
好了比較完整的代碼比較長
我傳了個到空間上自己看去
http://test.aymtv.com/url.asp
默認(rèn)的輸入欄里的代碼是crsky的一個下載地址你可以測試一下就知道了
點(diǎn)查看源代碼就可以看見這個asp文件的源代碼！
一切搞定 over 繼續(xù)去csdn混分去了
<%
Public Function Bytes2BSTR(v)
Dim r,i,t,n : r = ""
For i = 1 To LenB(v)
t = AscB(MidB(v,i,1))
If t < &H80 Then
r = r & Chr(t)
Else
n = AscB(MidB(v,i+1,1))
r = r & Chr(CLng(t) * &H100 + CInt(n))
i = i + 1
End If
Next
Bytes2BSTR = r
End Function
'==========================================================================================
If Request.QueryString="ViewSource" Then
Dim oFso : Set oFso=Server.CreateObject("Scripting.FileSystemObject")
Dim oFil : Set oFil=oFso.OpenTextFile(Server.MapPath("URL.Asp"))
Dim sTxt : sTxt=oFil.ReadAll()
oFil.Close : Set oFil=Nothing : Set oFso=Nothing
Response.ContentType="text/plain"
Response.Write sTxt
Response.ENd
End If
%><?xml version="1.0" encoding="gb2312" standalone="yes"?>
<!doctype html public "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns:v="http://www.eglic.com/">
<head>
<title></title>
<meta name="Generator" content="EditPlus" />
<meta name="Author" content="eglic" />
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<meta name="CharSet" content="GB2312" />
<link rel="stylesheet" type="text/css" href="/styles/default.css" />
<style type="text/css">
@media all{
}
</style>
<script language="javascript" src="/scripts/default.js"></script>
<script language="javascript" src="/scripts/xml.js"></script>
<script language="javascript">//<!--
//--></script>
</head>
<body>
<form action="" method="POST">
要檢測的URL：<input type="text" name="URL" size="50" value="<%
If Request.Form("URL")<>"" THen
Response.Write Trim(Request.Form("URL"))
Else
Response.Write "http://www.crsky.com/view_down.asp?downd_id=8&downd=0&ID=20780&down=yes"
End If
%>" />
<input type="submit" value="提交" />
<input type="button" value="查看源代碼" onclick="JavaScript:window.open('<%=URLSelf%>?ViewSource');" />
</form>
<%
Public Function GetAbsoluteURL(sUrl,ByRef iStep)
Dim bUrl,bDat
If iStep>15 Then
Err.Raise vbObejctError,"遞歸錯誤","遞歸嵌套超過15層可能會引起程序崩潰"
End If
If InStr(sUrl,"://")<=0 Then sUrl="http://" & sUrl
If InStr(sUrl,"?")>0 THen
Dim tmpUrl : tmpUrl=split(sUrl,"?")
bUrl=tmpUrl(0)
bDat=tmpUrl(1)
Else
bUrl=sUrl
bDat=""
End If
Response.Write "<p style=""border:solid 1px silver;border-top:solid 2px red;padding:5px;margin:2px;"">"
Response.Write "第 " & iStep & " 步："
Response.Write "正在準(zhǔn)備獲取 " & bUrl & "<br />"
iStep=iStep+1
if bDat<>"" Then Response.Write " >>參數(shù)： " & bDat & "<br />"
Dim oHttp : Set oHttp=Server.CreateObject("WinHttp.WinHttpRequest.5.1")
oHttp.Option(6)=0 '禁止自動Redirect，最關(guān)鍵的
'oHttp.Option()
oHttp.SetTimeouts 5000,5000,30000,5000
oHttp.Open "GET",sUrl,False
On Error Resume Next
oHttp.Send bDat
If Err.Number<>0 Then
Response.Write "<font color=""red"">發(fā)生錯誤：" & Err.Description & "</font><br />"
Err.Clear
GetAbsoluteURL=""
Set oHttp=Nothing
Response.Write "</p>"
Exit Function
End If
On Error Goto 0
Response.Write " >>HTTP 狀態(tài)：" & oHttp.Status & "<br />"
If oHttp.Status<>200 And oHttp.Status<>302 Then
Response.Write "<font color=""red"">HTTP錯誤：" & oHttp.StatusText & "</font><br />"
Err.Clear
GetAbsoluteURL=""
Set oHttp=Nothing
Response.Write "</p>"
Exit Function
End If
Dim sLoca
On Error Resume Next
sLoca=oHttp.getResponseHeader("Location")
If Err.Number<>0 Then
Err.Clear
sLoca=""
End If
On Error Goto 0
If sLoca = "" Then
Response.Write " >>Content-Type:" & oHttp.getResponseHeader("Content-Type") & "<br />"
Response.Write " >>Content-Length:"
On Error Resume Next
Response.Write oHttp.getResponseHeader("Content-Length")
If Err.Number<>0 THen Err.Clear
On Error Goto 0
Response.Write "<br />"
Response.Write " >>沒有返回Location頭，繼續(xù)分析頁面<br />"
If oHttp.getResponseHeader("Content-Type")="text/html" Then '是HTML類型才繼續(xù)處理
Dim sBody : sBody=Bytes2BStr(oHttp.responseBody)
Dim r : Set r=new Regexp
r.MultiLine=True
r.Global=True
r.IgnoreCase=True
r.Pattern="<meta.+http\-equiv\=\""refresh\"".+content=\""[^\;]+;url\=([^\""\s\>]*).*$"
If r.Test(sBody) Then
Response.Write " >>發(fā)現(xiàn) Refresh 地址<br />"
Dim m : Set m=r.Execute(sBody)
Dim tRefUrl : tRefUrl=r.Replace(m(0).Value,"$1")
If InStr(tRefUrl,"://")<=0 Then '沒有指定協(xié)議，按當(dāng)前URL的位置重新設(shè)置
Dim ind1 : ind1=InstrRev(sUrl,"/")
sUrl=Left(sUrl,ind1)
tRefUrl=sUrl & tRefUrl
End If
Set r=Nothing
Set oHttp=Nothing
Response.Write " >>準(zhǔn)備分析 <u>" & tRefUrl & "</u><br />"
Response.Write "</p>"
GetAbsoluteURL=GetAbsoluteURL(tRefUrl,iStep)
Exit Function
Else
Response.Write " >>沒發(fā)現(xiàn) Refresh Meta 轉(zhuǎn)向，這可能就是最終的URL<br />"
GetAbsoluteURL=sUrl
Set r=Nothing
Set oHttp=Nothing
Response.Write "</p>"
Exit Function
End If
Else
GetAbsoluteURL=sUrl
Set oHttp=Nothing
Response.Write "</p>"
Exit Function
End If
'這里要繼續(xù)分析網(wǎng)頁內(nèi)容
Else
Response.Write " >>Content-Type:" & oHttp.getResponseHeader("Content-Type") & "<br />"
Response.Write " >>Content-Length:"
On Error Resume Next
Response.Write oHttp.getResponseHeader("Content-Length")
If Err.Number<>0 THen Err.Clear
On Error Goto 0
Response.Write "<br />"
Response.Write " >><u>Location : " & sLoca& "</u><br />"
Response.Write "</p>"
'這里要生成新的URL
If InStr(sLoca,"://")<=0 Then
'沒有指定協(xié)議，按當(dāng)前URL的位置重新設(shè)置
Dim ind : ind=InstrRev(sUrl,"/")
sUrl=Left(sUrl,ind)
sLoca=sUrl & sLoca
End If
GetAbsoluteURL=GetAbsoluteURL(sLoca,iStep)
End If
End Function
If Request.Form("URL")<>"" THen
Dim iStep : iStep=1
Dim sAbs : sAbs=GetAbsoluteURL(Trim(Request.Form("URL")),iStep)
Response.Write "<strong style=""color:white;background-color:red;font-size:15px;padding:3px;margin:10px;"">最終結(jié)果是：" & sAbs & "</strong>"
End If
%>
<script src="/T/mystat.asp?siteid=1"></script>
</body>
</html>
相關(guān)文章
asp中使用MSXML2.ServerXMLHTTP實(shí)現(xiàn)異步請求例子
這篇文章主要介紹了asp中使用MSXML2.ServerXMLHTTP實(shí)現(xiàn)異步請求例子,本文還給出了MSXML2.ServerXMLHTTP異步請求代碼編寫最常犯的錯誤,需要的朋友可以參考下2014-08-08
沒有完美的東西，所以有漏洞在所難免，漏洞產(chǎn)生后隨之而來的就是各種應(yīng)對的招數(shù)，比如改數(shù)據(jù)庫的后綴、修改數(shù)據(jù)庫的名字等等。很多人以為只要這么做就可以解決問題了，但事實(shí)往往不如你我所愿，即使你這么做了也難逃被高手攻擊的命運(yùn)。2015-04-04
用ASP寫組件...2006-08-08
asp下用實(shí)現(xiàn)模板加載的的幾種方法總結(jié)
asp下html模板的加載方法，一般有以下幾種，大家可以根據(jù)情況自己決定，結(jié)果都是一樣的，都是好方法2008-01-01
asp下最常用的19個基本技巧...2007-11-11
防采集是很麻煩而且累人的事，你做的再好，別人要采還得采。累人就在于要防別人采集，還要不影響搜索引擎收錄（大部分個人站長的站的生存都寄于百度和Google）。所以要防采集，就得先不影響收錄，所以我們先要分析到如何分辨搜索爬蟲。2008-04-04
ASP頁面隨機(jī)添加字符實(shí)現(xiàn)防復(fù)制的代碼
ASP頁面隨機(jī)添加字符實(shí)現(xiàn)防復(fù)制的代碼...2007-08-08
asp下需要給圖片加水印一般就需要一些組件，aspjpeg是asp最常用的組件之一，下面的方法。2008-12-12
ASP中用ajax方式獲得session的實(shí)現(xiàn)代碼
前期做的時候，登錄方式順手用了ajax來做，登錄前先判斷在session中是否存在值，如果存在，那么無需登錄；如果不存在，那就彈出登錄頁面登錄。2011-05-05
這篇文章主要介紹了asp中創(chuàng)建多級目錄的兩段代碼,需要的朋友可以參考下2007-03-03