欧美bbbwbbbw肥妇,免费乱码人妻系列日韩,一级黄片

Global.asa文件技巧用法

 更新時間：2015年10月14日 09:57:58   投稿：lijiao  
本文介紹的是ASP的基礎(chǔ)知識，Global.asa文件技巧用法，希望對大家有幫助，一起來看。

Global.asa文件可以管理在ASP應(yīng)用中兩個非?？量痰膶ο螅篈pplication、Session。我們都知道，.asa是文件后綴名。是Active Server Application的首字母縮寫

它其實是一個可選文件，程序編寫者可以在該文件中指定事件腳本，并聲明具有會話和應(yīng)用程序作用域的對象。該文件的內(nèi)容不是用來給用戶顯示的，而是用來存儲事件信息和由應(yīng)用程序全局使用的對象。該文件必須存放在應(yīng)用程序的根目錄內(nèi)。每個應(yīng)用程序只能有一個Global.asa文件。

關(guān)于Global.asa文件最常見的錯誤概念是它能為一般的使用的函數(shù)和子程序用作書庫。Global.asa文件僅能用于創(chuàng)建對象的引用和俘獲啟動，以及結(jié)束Application對象和Session對象。

Global.asa文件主要基于會話級事件被訪問，在以下三種情況下被調(diào)用：

  • 當Application_OnStart或Application_OnEnd事件被觸發(fā)。
  • 當Session_OnStart或Session_OnEnd事件被觸發(fā)。
  • 當引用一個在Global.asa文件里被實例化的對象（Object）。

Global.asa的標準文件格式如下：

<SCRIPT LANGUAGE="VBScript" RUNAT="Server"> 
Sub Application_OnStart 
'Application_OnStart 當任何客戶首次訪問該應(yīng)用程序的首頁時運行 
End Sub  
Sub Session_OnStart  
'Session_OnStart 當客戶首次運行 ASP 應(yīng)用程序中的任何一個頁面時運行 
End Sub  
Sub Session_OnEnd  
'Session_OnEnd 當一個客戶的會話超時或退出應(yīng)用程序時運行 
End Sub  
Sub Application_OnEnd  
'Application_OnEnd 當該站點的 WEB 服務(wù)器關(guān)閉時運行 
End Sub  
</SCRIPT>

一、Session_onStart

先看一個控制用戶進入頁面的代碼：

1、Global.asa（放在被調(diào)試的虛擬目錄的根目錄下面）

<SCRIPT LANGUAGE="VBScript" RUNAT="Server"> 
Sub Session_OnStart '只要是用戶第一次登錄本站，則會跳轉(zhuǎn)到首頁 
response.redirect("http://www.webjx.com/") 
End Sub 
</SCRIPT>

然后調(diào)試當前虛擬目錄下的任何文件，你會發(fā)現(xiàn)所有頁面都跳轉(zhuǎn)向http://www.webjx.com/<
通過此“強制進入某頁”的例子，可以想象當首頁需要被關(guān)注的時候是非常有必要的。

下面就以一個“在線人數(shù)”的例子來繼續(xù)觀察Session_OnStart和Session_OnEnd事件

二、Session_onEnd

2、Global.asa（放在被調(diào)試的虛擬目錄的根目錄下面）

<SCRIPT LANGUAGE=VBScript RUNAT=Server> 
Sub Application_onStart '初始值為0 
Application("OnLine") = 0  
End Sub  
Sub Session_onStart '一個用戶訪問進行記數(shù)加1 
Application.Lock  
Application("OnLine") = Application("OnLine") + 1  
Application.Unlock  
End Sub  
Sub Session_OnEnd '一個用戶進程的結(jié)束，記數(shù)減1 （P.S.如果沒有該事件程序，則執(zhí)行的就是頁面訪問程序了。） 
Application.Lock  
Application("OnLine") = Application("OnLine") - 1  
Application.Unlock  
End Sub  
</SCRIPT>

3、online.asp

<% 
if request.querystring("logout")="true" then 
session.Abandon() 
response.end 
end if 
%> 
當前共有<%=Application("OnLine")%>在線 
<a href="online.asp?logout=true">退出</a>

你發(fā)現(xiàn)在該頁中只有一個Application("OnLine")，而且還是被顯示引用的。那么其值來自何方？這正是Global.asa文件的關(guān)鍵所在。你可以在本機依次打開個窗口，進行進行關(guān)閉窗口或退出兩種方法的調(diào)試。

三、繼續(xù)細化一下

上面的程序你會發(fā)現(xiàn)：當進行“退出”連接后關(guān)閉窗口和直接關(guān)閉窗口效果是不一樣的。因為Session存在時間的緣故，當直接進行關(guān)閉窗口，并不能觸發(fā)Session_OnEnd事件，所以該如何實現(xiàn)這個幾乎不可能的想法呢？

大家都知道，當網(wǎng)頁進行關(guān)閉的時候可以連帶一個onunload事件，那么該onunload只要能執(zhí)行Session的注銷功能不就我們需要的嗎？廢話少說，將online.asp進行修改

<% 
if request.querystring("logout")="true" then 
session.Abandon() 
response.end 
end if 
%> 
<body onunload=javascript:window.open("exit.asp")> 
當前共有<%=Application("OnLine")%>在線 
<a href="online.asp?logout=true">退出</a>

注意，online.asp進行onunload的時候會打開exit.asp，那只要在exit.asp中再設(shè)置session.Abandon()不就OK了。

exit.asp

<%session.Abandon()%> 
<script> 
self.close() 
</script>

當然，加了段Script腳本，目的是進行Session的注銷以后立即進行關(guān)閉本身。那現(xiàn)在基本一個在線統(tǒng)計的Web應(yīng)用就可以了。

四、深入研究Global.asa

從上面的調(diào)試中，舉一反三的你，一定會提出一個問題：如何控制注冊用戶在線人數(shù)？那下面幾個文件一個一個看：

5、Global.asa（放在被調(diào)試的虛擬目錄的根目錄下面）

<SCRIPT LANGUAGE="VBScript" RUNAT="Server"> 
Sub Application_OnStart 
application("online")=0 
End Sub 
Sub Session_OnStart 
End Sub 
Sub Session_OnEnd 
if session.contents("pass") then '判斷是否為登錄用戶的Session_OnEnd 
application.lock 
application("online")=application("online")-1 
application.unlock 
end if 
End Sub 
Sub Application_OnEnd 
End Sub 
</SCRIPT>

注意本Global.asa中的Session_OnStart塊不做任何事件。

因為一旦有用戶訪問服務(wù)器而不管用戶是否登錄，都會產(chǎn)生OnStart事件，而現(xiàn)在需要的只是登錄用戶的在線，所以不能在OnStart事件里使Application("online")加1。

又因為不管是否是登錄用戶的會話結(jié)束都會產(chǎn)生OnEnd事件（假如有訪客訪問了服務(wù)器但并不登錄，他的會話結(jié)束后也會產(chǎn)生OnEnd事件），所以在Session_OnEnd事件里用了句if語句來判斷是否為已登錄用戶的OnEnd事件，如果是才將在線人數(shù)減1。

并且值得注意的是：session.contents("pass")的使用，因為在OnEnd事件里禁止使用Session對象，但是可以用Session對象的集合來調(diào)用session變量。也就是說不能直接寫session("pass")，而是需要寫session.contents("pass")。

6、login.asp

<% 
if request.querystring("logout")="true" then 
session.Abandon() 
end if 
submitname=request.form("submit") 
if submitname="submit" then 
name=request.form("name") 
pwd=request.form("pwd") 
if name="cnbruce" and pwd="cnrose" then 
session("name")=name 
session("pass")=true 
else 
response.write "Error Name Or Pwd.<a href='login.asp'>Back</a>" 
response.end 
end if 
application.lock 
application("online")=application("online")+1 
application.unlock 
%>

當前注冊會員<%=application("online")%>人。

<a href="login.asp?logout=true">退出</a> 
<%else%> 
<form action="login.asp" method="post"> 
<input type="text" name="name"><br> 
<input type="password" name="pwd"><br> 
<input type="submit" name="submit" value="submit"> 
<%end if%>

只是簡單地檢測用名是cnbruce，密碼是cnrose的時候，生成一個session("pass")=true，就是放在Global.asa中判斷的。

五、繼續(xù)發(fā)揮想象

想想，再想想。僅僅統(tǒng)計有多少人在線是不夠的，還要判斷用戶的在線狀態(tài)。

可以想象辦法基本，當用戶登錄的時候，在login.asp里將online設(shè)為1（如果有數(shù)據(jù)庫則上傳），但用戶離線時將online設(shè)為0，要完善它，就要修改一下Session_OnEnd事件，在該事件里將online設(shè)為0（同樣將為0的值上傳）……

當然，Global.asa遠遠不止這些。不過我們現(xiàn)在先不著急全部掌握，當我們接觸到數(shù)據(jù)庫的時候再返回過來看，繼續(xù)研究該文件，相信到那時一定又會感悟到很多。所以，還是先把上面的這些吃透吧。

希望通過本文的介紹，能給你帶來幫助。

相關(guān)文章

最新評論