一、緣由

BLOB是指二進(jìn)制大對(duì)象，也就是英文Binary Large Object的縮寫。
在很多時(shí)候，我們是通過其他編程語言（如Java）訪問BLOB的字節(jié)數(shù)據(jù)，進(jìn)行字節(jié)級(jí)的操作的。
但是有些時(shí)候工作量很小，感覺專門為BLOB字節(jié)級(jí)操作而專門開發(fā)個(gè)程序，是比較麻煩的。于是我研究了一下如何直接在Oracle存儲(chǔ)過程里操作BLOB的字節(jié)數(shù)據(jù)。

二、辦法

2.1 基本操作

使用 length 函數(shù)，可以獲取blob的字節(jié)長(zhǎng)度。如 v_len := length(i_blob); 。
與字符串（如 varchar2 等）一樣，blob為 null 時(shí)，length的返回值是 null。故建議加上 nvl 做一下轉(zhuǎn)換，如 v_len := nvl(length(i_blob), 0); 。

為了避免 null 問題，可使用 empty_blob 函數(shù)，它的作用是返回一個(gè)長(zhǎng)度為0的blob。如 v_blob := empty_blob(); 。

empty_blob返回的blog只是一個(gè)初始化，它是不能修改字節(jié)數(shù)據(jù)的。于是需要使用 dbms_lob.createtemporary 來創(chuàng)建一個(gè)能進(jìn)行字節(jié)數(shù)據(jù)操作的臨時(shí)blob。如 dbms_lob.createtemporary(v_blob, TRUE); 。

2.2 DBMS_LOB包

為了便于BLOB類型的使用，Oracle官方提供了 DBMS_LOB 包，它提供了很多工具函數(shù)。例如先前我們使用了createtemporary函數(shù)。
DBMS_LOB所提供的過程有——

• APPEND：將源LOB中的內(nèi)容加到目的LOB中。
• CLOSE：關(guān)閉已經(jīng)打開的LOB。
• CREATETEMPORARY：在用戶的臨時(shí)表空間中，建立臨時(shí)LOB。
• FILECLOSE：關(guān)閉打開的BFILE定位符所指向的OS文件。
• FILECLOSEALL：關(guān)閉當(dāng)前會(huì)話已經(jīng)打開的所有BFILE文件。
• FILEEXISTS：確定file_loc對(duì)應(yīng)的OS文件是否存在，1：存在。0：不存在。
• FILEGETNAME：獲取BFILE定位符所對(duì)應(yīng)的目錄別名和文件名。
• FILEISOPEN：確定BFILE對(duì)應(yīng)的OS文件是否打開。
• FREETEMPORARY：釋放在默認(rèn)臨時(shí)表空間中的臨時(shí)LOB。
• FILEOPEN：打開文件。
• GETCHUNKSIZE：當(dāng)建立包含CLOB/BLOB列的表時(shí)，通過指定CHUNK參數(shù)可以指定操縱LOB需要分配的字節(jié)數(shù)（數(shù)據(jù)庫尺寸的整數(shù)倍）默認(rèn)為數(shù)據(jù)塊的尺寸。
• COPY：從源LOB中復(fù)制數(shù)據(jù)到目的LOB。
• ERASE：刪除LOB中全部或部分內(nèi)容。
• TRIM：將LOB值減少到指定的長(zhǎng)度。
• WRITE：向LOB中寫入數(shù)據(jù)。
• INSTR：返回特定樣式數(shù)據(jù)從LOB某偏移位置開始出現(xiàn)N次的具體位置。
• IDOPEN：確定LOB是否打開，打開：1，未打開：0。
• ISTEMPORARY：確定定位符是否為臨時(shí)LOB。
• LOADFROMFILE：將BFILE的部分或全部?jī)?nèi)容復(fù)制到目標(biāo)LOB變量。
• LOADBLOBFROMFILE：將BFILE數(shù)據(jù)裝載到BLOB中，并且在裝載后取得最新的偏移位置。
• OPEN：打開LOB，open_mode（只讀：dbms_lob.lob_readonly，寫：dbms_lob.lob_readwrite）。
• COMPARE：比較兩個(gè)同種數(shù)據(jù)類型的LOB的部分或全部值是否相同。
• GETLENGTH：獲取LOB的長(zhǎng)度。
• READ：從LOB中讀出數(shù)據(jù)。
• SUBSTR：與字符處理函數(shù)SUBSTR使用方法一樣。
• WRITEAPPEND：將緩沖區(qū)數(shù)據(jù)寫到LOB尾部。

有了DBMS_LOB包后，對(duì)于（變量級(jí)的）BLOB操作就比較方便了。例如我們想將兩個(gè)blob的內(nèi)容，連續(xù)拼接到1個(gè)blob中，則可以這樣做——

  function test_blob_join(i_blob1 in blob, i_blob2 in blob) return blob is
    v_rt blob := empty_blob();
  begin
    dbms_lob.createtemporary(v_rt, TRUE);  -- 分配臨時(shí)的 blob .
    dbms_lob.append(v_rt, i_blob1);        -- 拼接 i_blob1 .
    dbms_lob.append(v_rt, i_blob2);        -- 拼接 i_blob2 .
    return v_rt;
  end;

可這樣測(cè)試——

select PKG_FINGER.test_blob_join(hextoraw('0102'), hextoraw('A1A2')) from dual;

它返回blob的字節(jié)數(shù)據(jù)是 01 02 A1 A2。驗(yàn)證通過。

2.3 字節(jié)級(jí)操作與RAW數(shù)據(jù)類型

現(xiàn)在對(duì)實(shí)現(xiàn)BLOB的的變量級(jí)操作是沒有問題了。那么，該怎樣實(shí)現(xiàn)BLOB的字節(jié)級(jí)操作呢？
例如——怎么從blob中截取位置開始的一串字節(jié)？在blob中替換每個(gè)位置的字節(jié)？在blob的最后追加字節(jié)數(shù)據(jù)？
其實(shí)dbms_lob的 substr、write、writeappend 可分別解決這3個(gè)問題。
然后仔細(xì)一看，會(huì)發(fā)現(xiàn)這些過程使用了 RAW 類型。
對(duì)于RAW類型，很多資料是這樣說的——

RAW類型是Oracle中用于保存位串的一種數(shù)據(jù)類型，類似于CHAR，使用RAW（L) 方式聲明，最長(zhǎng)可達(dá)32767字節(jié)。

RAW與BLOB的關(guān)系——

• BLOB中的一段字節(jié)數(shù)據(jù)，就是RAW類型的。例如通過 dbms_lob.substr 截取得到的數(shù)據(jù)。
• 其次可根據(jù) RAW數(shù)據(jù) 去替換BLOB中的某段字節(jié)數(shù)據(jù)。即使用 dbms_lob.write 。
• 可在BLOB的最后追加 RAW數(shù)據(jù) 。即使用 dbms_lob.writeappend 。
• Oracle支持 RAW 隱式轉(zhuǎn)型為 BLOB 類型。

觀察dbms_lob的幫助文檔，會(huì)發(fā)現(xiàn)每個(gè)函數(shù)既有BLOB版，又有CLOB版。而且，CLOB版用VARCHAR2類型時(shí)，其BLOB版是RAW類型。即 RAW與VARCHAR2 是類似的，一個(gè)是字節(jié)串，一個(gè)是字符串。
許多常用的字符串函數(shù)也對(duì) RAW 是有效的。例如 length 與 sustr 。

RAW 可用十六進(jìn)制字符串來表示。所以一般使用 hextoraw 函數(shù)，將十六進(jìn)制字符串轉(zhuǎn)為RAW。例如 hextoraw('A1A2') 。
RAW 可看作十六進(jìn)制字符串。所以對(duì)raw變量使用length函數(shù)時(shí)，其返回值是 字節(jié)長(zhǎng)度的2倍（因?yàn)閷?duì)于十六進(jìn)制字符串，一個(gè)字節(jié)是用2個(gè)十六進(jìn)制字符表示的）。substr 等函數(shù)也存在同樣的情況。
還可以用 rawtohex，將 RAW類型的數(shù)據(jù) 轉(zhuǎn)換為 十六進(jìn)制字符串（VARCHAR2）。

2.4 UTL_RAW包

上面提到 RAW 的length結(jié)果是 字節(jié)長(zhǎng)度的2倍，它是不太方便的。這時(shí)可以使用 UTL_RAW包。例如 utl_raw.length的結(jié)果就是 字節(jié)長(zhǎng)度。
常見的UTL_RAW過程有——

• length：長(zhǎng)度計(jì)算函數(shù)，得到一個(gè)raw類型變量的長(zhǎng)度，單位為字節(jié)
• concat：拼接函數(shù)，用于拼接兩個(gè)raw類型變量
• substr：獲取子串函數(shù)
• bit_and：位與函數(shù)
• bit_or：位或函數(shù)
• bit_xor：位異或函數(shù)
• overlay：給指定字節(jié)賦值
• cast_to_raw：字符串 轉(zhuǎn) RAW
• cast_to_varchar2：RAW 轉(zhuǎn) varchar2
• cast_to_nvarchar2：RAW 轉(zhuǎn) nvarchar2
• cast_to_number：RAW 轉(zhuǎn) number
• cast_from_number：number 轉(zhuǎn) RAW
• cast_to_binary_integer：RAW 轉(zhuǎn) binary_integer
• cast_from_binary_integer：binary_integer 轉(zhuǎn) RAW

三、使用心得

3.1 32位整數(shù)轉(zhuǎn)換函數(shù)

最開始不知道 binary_integer就是32位整數(shù)。于是自己寫了32位整數(shù)與 RAW 的轉(zhuǎn)換函數(shù)。雖然現(xiàn)在用不上了，但覺得它們還是很適合作為應(yīng)用示范的。

  -- 將數(shù)字轉(zhuǎn)為 raw(4)類型的 大端方式32位整數(shù) .
  function TO_INT32BE(i_src in number) return raw is
    v_src number;
    v_hexstr varchar2(20);
    v_rt raw(4);
  begin
    v_src := i_src;
    if (v_src<0) then
      v_src:=v_src + 4294967296;    -- 為了支持負(fù)數(shù).
    end if;
    v_hexstr := '0000000' || trim(to_char(v_src,'XXXXXXXX'));
    v_hexstr := substr(v_hexstr, length(v_hexstr)-7, length(v_hexstr));
    v_rt := hextoraw(v_hexstr);
    return v_rt;
  end;
  -- 將數(shù)字轉(zhuǎn)為 raw(4)類型的 小端方式32位整數(shù) .
  function TO_INT32LE(i_src in number) return raw is
    v_src number;
    v_hexstr varchar2(20);
    v_rt raw(4);
  begin
    v_src := i_src;
    if (v_src<0) then
      v_src:=v_src + 4294967296;    -- 為了支持負(fù)數(shù).
    end if;
    v_hexstr := '0000000' || trim(to_char(v_src,'XXXXXXXX'));
    v_hexstr := substr(v_hexstr, length(v_hexstr)-7, length(v_hexstr));
    v_hexstr := substr(v_hexstr, 7, 2)
      || substr(v_hexstr, 5, 2)
      || substr(v_hexstr, 3, 2)
      || substr(v_hexstr, 1, 2)
      ;
    v_rt := hextoraw(v_hexstr);
    return v_rt;
  end;
  -- 將 存儲(chǔ)在raw(4)中的大端方式32位整數(shù) 轉(zhuǎn)為數(shù)字. 值域?yàn)?0~4294967295 .
  function FROM_INT32BE(i_src in raw) return number is
    v_src raw(8);
    v_hexstr varchar2(20):='';
    v_rt number:=0;
  begin
    if ( (nvl(length(i_src), 0)<=0) ) then
      return v_rt;
    end if;
    if (length(i_src) >= 8) then    -- length、substr均把 raw 的1個(gè)字節(jié)看作 2個(gè)（十六進(jìn)制）字符.
      v_src := substr(i_src, 1, 8);
      v_hexstr := rawtohex(v_src);
    else
      v_hexstr := '000000' || rawtohex(i_src);
      v_hexstr := substr(v_hexstr, length(v_hexstr)-7, length(v_hexstr));
    end if;
    v_rt := to_number(v_hexstr,'XXXXXXXX');
    return v_rt;
  end;
  -- 將 存儲(chǔ)在raw(4)中的小端方式32位整數(shù) 轉(zhuǎn)為數(shù)字. 值域?yàn)?0~4294967295 .
  function FROM_INT32LE(i_src in raw) return number is
    v_src raw(8);
    v_hexstr varchar2(20):='';
    v_rt number:=0;
  begin
    if ( (nvl(length(i_src), 0)<=0) ) then
      return v_rt;
    end if;
    if (length(i_src) >= 8) then    -- length、substr均把 raw 的1個(gè)字節(jié)看作 2個(gè)（十六進(jìn)制）字符.
      v_src := substr(i_src, 1, 8);
      v_hexstr := rawtohex(v_src);
    else
      v_hexstr := rawtohex(i_src) || '000000';
      v_hexstr := substr(v_hexstr, 1, 8);
    end if;
    v_hexstr := substr(v_hexstr, 7, 2)
      || substr(v_hexstr, 5, 2)
      || substr(v_hexstr, 3, 2)
      || substr(v_hexstr, 1, 2)
      ;
    v_rt := to_number(v_hexstr,'XXXXXXXX');
    return v_rt;
  end;

3.2 將32位整數(shù)追加到blob

很多時(shí)候需要給blob追加一個(gè) 32位整數(shù)?，F(xiàn)在利用上面的函數(shù)，可以這樣做——

      v_tempraw := TO_INT32LE(nvl(i_int32, 0));
      dbms_lob.writeappend(v_blob, 4, v_tempraw);

（完）

參考文獻(xiàn)

• Oracle Database Online Documentation / DBMS_LOB . https://docs.oracle.com/cd/E11882_01/timesten.112/e21645/d_lob.htm#TTPLP600
• Oracle Database Online Documentation / UTL_RAW . https://docs.oracle.com/cd/E11882_01/timesten.112/e21645/u_raw.htm#TTPLP072
• 旺仔丶小饅頭《DBMS_LOB》 . https://www.cnblogs.com/wang-chen/p/5756475.html
• Hornsey《Oracle RAW類型基本操作函數(shù)及使用示例》 . https://blog.csdn.net/nalw2012/article/details/72466256
• jimeper《ORACLE十進(jìn)制與十六進(jìn)制的轉(zhuǎn)換》 . https://www.cnblogs.com/jimeper/archive/2013/01/24/2875245.html

到此這篇關(guān)于Oracle存儲(chǔ)過程里操作BLOB的字節(jié)數(shù)據(jù)的辦法的文章就介紹到這了,更多相關(guān)Oracle BLOB 字節(jié)數(shù)據(jù)內(nèi)容請(qǐng)搜索腳本之家以前的文章或繼續(xù)瀏覽下面的相關(guān)文章希望大家以后多多支持腳本之家！

最新評(píng)論