電腦怎么實(shí)現(xiàn)批處理ping多個ip? 批處理掃描網(wǎng)段技巧

百度經(jīng)驗(yàn) 發(fā)布時間：2020-07-21 10:14:36 作者：卟一樣

電腦怎么實(shí)現(xiàn)批處理ping多個ip？我們需要憑一個網(wǎng)段，看看ip的使用情況，該怎么ping多個ip呢？下面我們就來看看批處理掃描網(wǎng)段技巧，需要的朋友可以參考下

很多人都會遇到需要ping一個網(wǎng)段，看哪些IP地址有在使用的情況，網(wǎng)上下載的一些群PING軟件要么殺毒軟件報(bào)毒，要么顯示結(jié)果每次不一樣，于是我綜合了網(wǎng)上各種批處理Ping命令后，自己整理了一個批處理，希望能幫助到有需要的朋友，下面我先演示使用過程，最后給出批處理代碼。

1、雙擊運(yùn)行批處理文件，會彈出一個命令窗口，要求輸入IP段，如果不輸入，直接按回車的話，則默認(rèn)為192.168.16段。

這里我輸入我的路由分配的IP段，192.168.3并按回車

2、接著會要求輸入IP地址起始位，如果不輸入，直接按回車的話，則默認(rèn)為1。

這里我輸入10

3、最后會要求輸入IP地址結(jié)束位，如果不輸入，直接按回車的話，則默認(rèn)為255。

這里我輸入40

4、開始掃描，會顯示起始和結(jié)束IP地址，以確認(rèn)之前沒有輸入錯誤。

運(yùn)行的時候不會有其他提示，如果不許要等待完成，可以直接關(guān)閉窗口以提前結(jié)束本次掃描。

5、掃描完成后，按任意鍵退出，窗口會自動關(guān)閉。

6、在批處理命令文件所在的文件夾，會生成對應(yīng)的文本文件，里面就有本次掃描的結(jié)果（僅記錄有通的結(jié)果）

7、以下為批處理的代碼全文，將其保存在文本文件中，把文本文件的后綴txt替換成bat即可。

@echo off
color F0
rem 設(shè)置窗口背景色為白色，文字顏色為黑色
title 批處理掃網(wǎng)段(By TaoGe)
rem 設(shè)置窗口標(biāo)題
echo.
echo 輸入你要掃描的IP段，直接按回車則為192.168.16：
set /p IpDuan=
rem 將用戶輸入賦值給IpDuan變量
if "%IpDuan%"=="" (set IpDuan=192.168.16)
rem 判斷IpDuan變量是否賦值，如果為空，則賦值為192.168.16
echo 輸入你要掃描的IP起始位，直接按回車則為1：
set /p QiShi=
rem 將用戶輸入賦值給QiShi變量
if "%QiShi%"=="" (set QiShi=1)
rem 判斷QiShi變量是否賦值，如果為空，則賦值為1
echo 輸入你要掃描的IP結(jié)束位，直接按回車則為255：
set /p JieShu=
rem 將用戶輸入賦值給JieShu變量
if "%JieShu%"=="" (set JieShu=255)
rem 判斷JieShu變量是否賦值，如果為空，則賦值為255
echo 起始IP：%IpDuan%.%QiShi%  
rem 顯示起始IP
echo 結(jié)束IP：%IpDuan%.%JieShu%  
rem 顯示結(jié)束IP
echo ======================================================= >>Ping-%IpDuan%.txt
rem 記錄分割線
echo 開始時間：%date%%time% >>Ping-%IpDuan%.txt
rem 記錄開始時間
echo 起始IP：%IpDuan%.%QiShi% >>Ping-%IpDuan%.txt  
rem 記錄起始IP
echo 結(jié)束IP：%IpDuan%.%JieShu% >>Ping-%IpDuan%.txt 
rem 記錄結(jié)束IP
echo 正在掃描，請等待...
echo 提前結(jié)束請直接關(guān)閉窗口
@for /l %%n in (%QiShi%,1,%JieShu%) do @ping -w 600 -n 1 %IpDuan%.%%n|find  /i "ttl" >>Ping-%IpDuan%.txt
rem 開始執(zhí)行
echo 結(jié)束時間：%date% %time%  >>Ping-%IpDuan%.txt
rem 記錄結(jié)束時間
echo ======================================================= >>Ping-%IpDuan%.txt
rem 記錄分割線
echo 掃描完畢,按任意鍵退出...&pause>nul