為指定控件的點擊行為定義一個用戶函數(shù)。
GUISetOnEvent ( 事件ID, "函數(shù)名" [, 窗口句柄] )
參數(shù)
| 事件ID | 見下面的 狀態(tài)表。 |
| 函數(shù)名 | 要調(diào)用的用戶函數(shù)。 |
| 窗口句柄 | [可選參數(shù)] 窗口句柄，可由 GUICreate 的返回值獲得（若缺省則使用上一次用過的句柄）。 |
返回值
| 成功： | 返回值為1。 |
| 失敗： | 返回值為0。 |
注意
OnEvent 函數(shù)僅當選項 GUIOnEventMode 的值為1時才能被調(diào)用，而在此模式下 GUIGetMsg 將完全無效。| 事件 Id | 解釋 |
| $GUI_EVENT_CLOSE | 對話框（窗口）正被關閉（相關按鈕被點擊或系統(tǒng)菜單項被選中） |
| $GUI_EVENT_MINIMIZE | 對話框（窗口）被最小化（窗口標題欄上的最小化按鈕被點擊） |
| $GUI_EVENT_RESTORE | 對話框（窗口）被還原（任務欄圖標被點擊） |
| $GUI_EVENT_MAXIMIZE | 對話框（窗口）被最大化（窗口標題欄上的最大化按鈕被點擊） |
| $GUI_EVENT_MOUSEMOVE | 鼠標指針移動 |
| $GUI_EVENT_PRIMARYDOWN | 鼠標的主要按鈕被按下 |
| $GUI_EVENT_PRIMARYUP | 鼠標的主要按鈕被松開 |
| $GUI_EVENT_SECONDARYDOWN | 鼠標的次要按鈕被按下 |
| $GUI_EVENT_SECONDARYUP | 鼠標的次要按鈕被松開 |
相關
GUIOnEventMode（選項）, GUICtrlSetOnEvent
示例
#include <GUIConstants.au3>
Opt("GUICoordMode",2)
Opt("GUIResizeMode", 1)
Opt("GUIOnEventMode", 1)
$parent1 = GUICreate("Parent1")
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_RESTORE, "SpecialEvents")
$ok1 = GUICtrlCreateButton ("OK", 10, 30, 50)
GUICtrlSetOnEvent(-1, "OKPressed")
$cancel1 = GUICtrlCreateButton ( "Cancel", 0, -1)
GUICtrlSetOnEvent(-1, "CancelPressed")
GUISetState(@SW_SHOW)
; 閑置
While 1
Sleep(10)
Wend
; END
Func OKPressed()
MsgBox(0, "OK 按鈕被按下", "ID=" & @GUI_CTRLID & " WinHandle=" & @GUI_WINHANDLE & " CtrlHandle=" & @GUI_CTRLHANDLE)
EndFunc
Func CancelPressed()
MsgBox(0, "Cancel 按鈕被按下", "ID=" & @GUI_CTRLID & " WinHandle=" & @GUI_WINHANDLE & " CtrlHandle=" & @GUI_CTRLHANDLE)
EndFunc
Func SpecialEvents()
Select
Case @GUI_CTRLID = $GUI_EVENT_CLOSE
MsgBox(0, "關閉按鈕被按下", "ID=" & @GUI_CTRLID & " WinHandle=" & @GUI_WINHANDLE)
Exit
Case @GUI_CTRLID = $GUI_EVENT_MINIMIZE
MsgBox(0, "窗口被最小化", "ID=" & @GUI_CTRLID & " WinHandle=" & @GUI_WINHANDLE)
Case @GUI_CTRLID = $GUI_EVENT_RESTORE
MsgBox(0, "窗口被還原", "ID=" & @GUI_CTRLID & " WinHandle=" & @GUI_WINHANDLE)
EndSelect
EndFunc