欧美bbbwbbbw肥妇,免费乱码人妻系列日韩,一级黄片

; 例子腳本, 演示 COM 事件函數(shù)的用法
; 需要至少 AutoIt 測(cè)試版 3.1.1.104 !
;
; 參閱: http://msdn.microsoft.com/workshop/browser/webbrowser/reference/objects/internetexplorer.asp

; 使用一個(gè)非常簡(jiǎn)單的 GUI 顯示事件的結(jié)果.
#include "GUIConstantsEx.au3"
$GUIMain=GUICreate              ( "事件測(cè)試",       600,500 )
$GUIEdit=GUICtrlCreateEdit      ( "測(cè)試記錄:" & @CRLF,  10, 20, 580, 400)
$GUIProg=GUICtrlCreateProgress  (                       10,  5, 580,  10)
$GUIExit=GUICtrlCreateButton    ( "關(guān)閉",          250, 450, 80,  30)
GUISetState ()       ;Show GUI

; 準(zhǔn)備 IE 瀏覽器作為測(cè)試主題
$oIE=ObjCreate("InternetExplorer.Application.1")
With $oIE
    .Visible=1
    .Top = (@DesktopHeight-400)/2
    .Height=400         ; 使瀏覽器比我們的 GUI 稍微小一點(diǎn).
    .Width=600
    .Silent=1           ; 不顯示 IE 的對(duì)話框
    $IEWnd=HWnd(.hWnd)  ; 記住窗口狀態(tài), 以防萬(wàn)一用戶將其關(guān)閉
EndWith

; 為 IE 瀏覽器選擇特定的接口 'DWebBrowserEvents' because the IE is subject
; 因?yàn)?IE 受制于 Visual Studio 與 Adobe Acrobat Reader 軟件的修改.
; 如果你已安裝 IE 插件,AutoIt 可能不能自動(dòng)尋找到正確的接口.
$EventObject=ObjEvent($oIE,"IEEvent_","DWebBrowserEvents")
if @error then
   Msgbox(0,"AutoIt COM 測(cè)試", _
    "ObjEvent: 不能使用事件接口 'DWebBrowserEvents'. 錯(cuò)誤代碼: " & hex(@error,8))
   exit
endif

; 現(xiàn)在開(kāi)始加載實(shí)例網(wǎng)頁(yè).
$URL = "http://www.AutoItScript.com/"
$oIE.Navigate( $URL )          
sleep(1000)             ; 給網(wǎng)頁(yè)的加載時(shí)間

GUISwitch ( $GUIMain )  ; 切轉(zhuǎn)到我們的 GUI, 以防萬(wàn)一 IE 竊取焦點(diǎn)

; 等候用戶關(guān)閉 GUI.
While 1
   $msg = GUIGetMsg()
   If $msg = $GUI_EVENT_CLOSE or $msg = $GUIExit Then ExitLoop
Wend

$EventObject.Stop   ; 告訴 IE 我們不接收事件.
$EventObject=0      ; 取消事件對(duì)象
If WinExists($IEWnd) then $oIE.Quit     ; 關(guān)閉 IE 窗口
$oIE=0              ; 從內(nèi)存中移除 IE (不是必需的).

GUIDelete ()        ; 刪除 GUI

exit                ; 結(jié)束我們的演示.

; 一些 IE 事件函數(shù)
; 參閱: http://msdn.microsoft.com/workshop/browser/webbrowser/reference/objects/webbrowser.asp

Func IEEvent_BeforeNavigate($URL, $Flags, $TargetFrameName, $PostData, $Headers, $Cancel)
;   注意: 申明的內(nèi)容與 MSDN 的敘述不同.
    GUICtrlSetData ( $GUIEdit, "定位之前: " & $URL & " 標(biāo)志: " & $Flags & " 框架: " & $TargetFrameName & " 動(dòng)態(tài)地址: " & $PostData & " 標(biāo)題: " & $Headers & " 刪除: " & $Cancel  & @CRLF  , "附加" )
EndFunc

Func IEEvent_ProgressChange($Progress,$ProgressMax)
    If $ProgressMax > 0 Then
        GUICtrlSetData($GUIProg, ($Progress * 100) / $ProgressMax )
    EndIf
EndFunc

Func IEEvent_StatusTextChange($Text)
    GUICtrlSetData ( $GUIEdit, "IE 狀態(tài)文本改變?yōu)? " & $Text & @CRLF  , "附加" )
EndFunc

Func IEEvent_PropertyChange( $szProperty)
    GUICtrlSetData ( $GUIEdit, "IE 改變特性后的值: " & $szProperty & @CRLF  , "附加" )
EndFunc

Func IEEvent_DownloadComplete()
    GUICtrlSetData ( $GUIEdit, "IE 完成導(dǎo)航操作" & @CRLF  , "附加" )
EndFunc

Func IEEvent_NavigateComplete($URL)  
;   注意: 說(shuō)明的內(nèi)容與 MSDN 的敘述不同.
    GUICtrlSetData ( $GUIEdit, "IE 加載 URL 完成: " & $URL & @CRLF  , "附加" )
EndFunc

Func IEEvent_($EventName)  
; 這是捕捉未定義事件的一個(gè)可選事件函數(shù).
; 參數(shù)包含被調(diào)用事件的名字.
    GUICtrlSetData ( $GUIEdit, "未捕捉事件: " & $EventName & @CRLF  , "附加" )
EndFunc
provider with jb51.net (unicode)