欧美bbbwbbbw肥妇,免费乱码人妻系列日韩,一级黄片

腳本運行時庫  

處理文件

有兩種主要的文件處理類型：

創(chuàng)建文件

創(chuàng)建空文本文件（有時被叫做“文本流”）有三種方法。

第一種方法是用 CreateTextFile 方法。下面的示例示范了如何用 CreateTextFile 方法創(chuàng)建文本文件：

[VBScript]
Dim fso, f1
Set fso = CreateObject("Scripting.FileSystemObject")
Set f1 = fso.CreateTextFile("c:\testfile.txt", True)
[JScript]
var fso, f1;
fso = new ActiveXObject("Scripting.FileSystemObject");
f1 = fso.CreateTextFile("c:\\testfile.txt", true);

創(chuàng)建文本文件的第二種方法是，使用 FileSystemObject 對象的 OpenTextFile 方法，并設(shè)置 ForWriting 標(biāo)志。

[VBScript]
Dim fso, ts
Const ForWriting = 2
Set fso = CreateObject("Scripting. FileSystemObject")
Set ts = fso.OpenTextFile("c:\test.txt", ForWriting, True)
[JScript]
var fso, ts;
var ForWriting= 2;
fso = new ActiveXObject("Scripting.FileSystemObject");
ts = fso.OpenTextFile("c:\\test.txt", ForWriting, true);

創(chuàng)建文本文件的第三種方法是，使用 OpenAsTextStream 方法，并設(shè)置 ForWriting 標(biāo)志。要使用這種方法，使用下面的代碼：

[VBScript]
Dim fso, f1, ts
Const ForWriting = 2
Set fso = CreateObject("Scripting.FileSystemObject")
fso.CreateTextFile ("c:\test1.txt")
Set f1 = fso.GetFile("c:\test1.txt")
Set ts = f1.OpenAsTextStream(ForWriting, True)
[JScript]
var fso, f1, ts;
var ForWriting = 2;
fso = new ActiveXObject("Scripting.FileSystemObject");
fso.CreateTextFile ("c:\\test1.txt");
f1 = fso.GetFile("c:\\test1.txt");
ts = f1.OpenAsTextStream(ForWriting, true);

添加數(shù)據(jù)到文件中

一旦創(chuàng)建了文本文件，使用下面的三個步驟向文件添加數(shù)據(jù)：

打開文本文件。

寫入數(shù)據(jù)。

關(guān)閉文件。

要打開現(xiàn)有的文件，則使用 FileSystemObject 對象的 OpenTextFile 方法或 File 對象的 OpenAsTextStream 方法。

要寫數(shù)據(jù)到打開的文本文件，則根據(jù)下表所述任務(wù)使用 TextStream 對象的 Write、WriteLine 或 WriteBlankLines 方法。

任務(wù) 方法
向打開的文本文件寫數(shù)據(jù)，不用后續(xù)一個新行字符。 Write
向打開的文本文件寫數(shù)據(jù)，后續(xù)一個新行字符。 WriteLine
向打開的文本文件寫一個或多個空白行。 WriteBlankLines

要關(guān)閉一個打開的文件，則使用 TextStream 對象的 Close 方法。

注意   新行字符包含一個或幾個字符（取決于操作系統(tǒng)），以把光標(biāo)移動到下一行的開始位置（回車/換行）。注意某些字符串末尾可能已經(jīng)有這個非打印字符了。

下面的例子示范了如何打開文件，和同時使用三種寫方法來向文件添加數(shù)據(jù)，然后關(guān)閉文件：

[VBScript]
Sub CreateFile()
   Dim fso, tf
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set tf = fso.CreateTextFile("c:\testfile.txt", True)
   ' 寫一行，并帶有一個新行字符。
   tf.WriteLine("Testing 1, 2, 3.") 
   '  向文件寫三個新行字符。      
   tf.WriteBlankLines(3) 
   ' 寫一行。
   tf.Write ("This is a test.") 
   tf.Close
End Sub
[JScript]
function CreateFile()
{
   var fso, tf;
   fso = new ActiveXObject("Scripting.FileSystemObject");
   tf = fso.CreateTextFile("c:\\testfile.txt", true);
   // 寫一行，并帶有一個新行字符。
   tf.WriteLine("Testing 1, 2, 3.") ;
   // 向文件寫三個新行字符。
   tf.WriteBlankLines(3) ;
   // 寫一行。
   tf.Write ("This is a test.");
   tf.Close();
}

讀取文件

要從文本文件讀取數(shù)據(jù)，則使用 TextStream 對象的 Read、ReadLine 或 ReadAll 方法。下表描述了不同的任務(wù)應(yīng)使用哪種方法。

任務(wù) 方法
從文件讀取指定數(shù)量的字符。 Read
讀取一整行（一直到但不包括新行字符）。 ReadLine
讀取文本文件的整個內(nèi)容。 ReadAll

如果使用 Read 或 ReadLine 方法，并且想跳過數(shù)據(jù)的特殊部分，則使用 Skip 或 SkipLine 方法。read 方法的結(jié)果文本存在一個字符串中，該字符串可以顯示在一個控件中，也可以用字符串函數(shù)（如 Left、Right 和 Mid）來分析，連接等等。

下面的例子示范了如何打開文件，和如何寫數(shù)據(jù)到文件中并從文件讀取數(shù)據(jù)：

[VBScript]
Sub ReadFiles
   Dim fso, f1, ts, s
   Const ForReading = 1
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set f1 = fso.CreateTextFile("c:\testfile.txt", True)
   ' 寫入一行。
   Response.Write "Writing file <br>"
   f1.WriteLine "Hello World"
   f1.WriteBlankLines(1)
   f1.Close
   ' 讀取文件內(nèi)容。
   Response.Write "Reading file <br>"
   Set ts = fso.OpenTextFile("c:\testfile.txt", ForReading)
   s = ts.ReadLine
   Response.Write "File contents = '" & s & "'"
   ts.Close
End Sub
[JScript]
function ReadFiles()
{
   var fso, f1, ts, s;
   var ForReading = 1;
   fso = new ActiveXObject("Scripting.FileSystemObject");
   f1 = fso.CreateTextFile("c:\\testfile.txt", true);
   // 寫入一行。
   Response.Write("Writing file <br>");
   f1.WriteLine("Hello World");
   f1.WriteBlankLines(1);
   f1.Close();
   // 讀取文件內(nèi)容。
   Response.Write("Reading file <br>");
   ts = fso.OpenTextFile("c:\\testfile.txt", ForReading);
   s = ts.ReadLine();
   Response.Write("File contents = '" + s + "'");
   ts.Close();
}

移動、復(fù)制和刪除文件

FSO 對象模型各有兩種方法移動、復(fù)制和刪除文件，如下表所述。

任務(wù) 方法
移動文件 File.Move 或 FileSystemObject.MoveFile
復(fù)制文件 File.Copy 或 FileSystemObject.CopyFile
刪除文件 File.Delete 或 FileSystemObject.DeleteFile

下面示例在驅(qū)動器 C 的根目錄中創(chuàng)建一個文本文件，向其中寫一些信息，然后把它移動到 \tmp 目錄中，并在 \temp 中做一個備份，最后把它們從兩個目錄中刪掉。

要運行下面的示例，需要先在驅(qū)動器 C 的根目錄中創(chuàng)建 \tmp 和 \temp 目錄：

[VBScript]
Sub ManipFiles
   Dim fso, f1, f2, s
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set f1 = fso.CreateTextFile("c:\testfile.txt", True)
   Response.Write "Writing file <br>"
   ' 寫入一行。
   f1.Write ("This is a test.")
   ' 關(guān)閉寫入到的文件。
   f1.Close
   Response.Write "Moving file to c:\tmp <br>"
   ' 獲取到 C:\ 根目錄中文件的句柄。
   Set f2 = fso.GetFile("c:\testfile.txt")
   ' 將文件移到 \tmp 目錄。
   f2.Move ("c:\tmp\testfile.txt")
   Response.Write "Copying file to c:\temp <br>"
   ' 將文件復(fù)制到 \temp。
   f2.Copy ("c:\temp\testfile.txt")
   Response.Write "Deleting files <br>"
   ' 獲得文件當(dāng)前位置的句柄。
   Set f2 = fso.GetFile("c:\tmp\testfile.txt")
   Set f3 = fso.GetFile("c:\temp\testfile.txt")
   ' 刪除文件。
   f2.Delete
   f3.Delete
   Response.Write "All done!"
End Sub
[JScript]
function ManipFiles()
{
   var fso, f1, f2, s;
   fso = new ActiveXObject("Scripting.FileSystemObject");
   f1 = fso.CreateTextFile("c:\\testfile.txt", true);
   Response.Write("Writing file <br>");
   // 寫入一行。
   f1.Write("This is a test.");
   // 關(guān)閉寫入到的文件。
   f1.Close();
   Response.Write("Moving file to c:\\tmp <br>");
   // 獲取到 C:\ 根目錄中文件的句柄。
   f2 = fso.GetFile("c:\\testfile.txt");
   // 將文件移到 \tmp 目錄。
   f2.Move ("c:\\tmp\\testfile.txt");
   Response.Write("Copying file to c:\\temp <br>");
   // 將文件復(fù)制到 \temp。
   f2.Copy ("c:\\temp\\testfile.txt");
   Response.Write("Deleting files <br>");
   // 獲得文件當(dāng)前位置的句柄。
   f2 = fso.GetFile("c:\\tmp\\testfile.txt");
   f3 = fso.GetFile("c:\\temp\\testfile.txt");
   // 刪除文件。
   f2.Delete();
   f3.Delete();
   Response.Write("All done!");
}