下面的演練將介紹典型的網絡管理員或其他 IT 專業(yè)人士如何使用 WSH 5.6 創(chuàng)建用于完成有用任務的過程。

注意   該演練是用 VBScript 展示的。用于創(chuàng)建這些腳本的過程對于使用 VBScript 或 JScript 的開發(fā)人員而言幾乎是相同的。

在該演練過程中，您將會執(zhí)行以下操作：

• 創(chuàng)建一個腳本，用來在若干遠程計算機上創(chuàng)建一個公用的共享點，以便將文件放入其中。
• 創(chuàng)建一個腳本，用來在若干遠程計算機上創(chuàng)建一個公用的打印設備連接，并將其設為默認打印設備。

為完成該演練，所有遠程計算機都必須配置正確以便啟用遠程 WSH。有關啟用這些安全設置的詳細信息，請參閱設置遠程 WSH。

注意   下面的代碼來自本文檔中包含的示例。若要查看整個示例，請參閱 WSH 網絡管理員示例腳本。

創(chuàng)建變量和常數

創(chuàng)建必要的變量和常數

1. 在您的文本腳本編輯器中，輸入下列變量。

   Dim FSO
   Dim Services
   Dim SecDescClass
   Dim SecDesc
   Dim Trustee
   Dim ACE
   Dim Share
   Dim InParam
   Dim Network

2. 在您的文本腳本編輯器中輸入常數，更改值的大小以反映適用于網絡環(huán)境的 UNC 名稱和路徑。

   Const FolderName = "C:\Public"
   Const AdminServer = "\\AdminMachine"
   Const ShareName = "Pubs"
   Const PrinterShare = "\\CorpPrinters\PrinterShare"

與打印機連接并將其設為默認打印機

將計算機與公用的打印設備連接

• 在您的文本腳本編輯器中，輸入用于創(chuàng)建打印設備的代碼。該代碼使用在上一步中初始化的 Network 變量和 PrinterShare 常數。

  Set Network = CreateObject("Wscript.Network")
  Network.AddWindowsPrinterConnection PrinterShare

將計算機設為默認打印設備

• 在您的文本腳本編輯器中，輸入用于設置默認打印設備的代碼。該代碼使用在第一步中初始化的 Network 變量和 PrinterShare 常數。

  Network.SetDefaultPrinter PrinterShare

創(chuàng)建公用共享點，將文件復制到其中，并將其共享

在計算機上創(chuàng)建公用共享點

• 在您的文本腳本編輯器中，輸入用于創(chuàng)建文件系統對象 (FSO) 以及創(chuàng)建文件夾的代碼。該腳本將驗證文件夾是否存在。如果文件夾不存在，腳本就會創(chuàng)建它。該代碼使用在第一步中初始化的 FSO 變量和 FolderName 常數。

  Set FSO = CreateObject("Scripting.FileSystemObject")
  If Not FSO.FolderExists(FolderName) Then 
     FSO.CreateFolder(FolderName)
  End If

將文件復制到新建文件夾中

• 在您的文本腳本編輯器中，輸入用于創(chuàng)建文件系統對象 (FSO) 以及將本地計算機上的文件復制到遠程計算機上的代碼。該代碼使用在第一步中初始化的 FSO 變量和 FolderName 常數。

  Call FSO.CopyFile(AdminServer & "\Public\Images\*.*"，FolderName)

用 WMI 將新建文件夾設為共享點

• 在您的文本腳本編輯器中，輸入使用 Windows 管理規(guī)范 (WMI) 創(chuàng)建共享點的代碼。共享點設立在上面所生成的文件夾中。腳本首先與 WMI 連接。接著，它設置安全模擬級別和 Windows NT 權限，以允許您設置任意訪問控制列表 (DACL) 和安全訪問控制列表 (SACL)。接著，它為新共享點創(chuàng)建一個新的安全說明符，并設置一對訪問控制項 (ACE)。最后，它將用新的安全說明符創(chuàng)建新的共享點。該代碼使用在第一步中初始化的 Services、SecDescClass、SecDesc、Trustee、ACE、Share 和 InParam 變量，以及 FolderName、AdminShare 和 ShareName 常數。

  注意   WMI 是基于 Web 的企業(yè)管理 (WBEM) 的功能強大而又高級的技術。WMI 主要用于訪問和管理企業(yè)環(huán)境中的管理信息。有關 WMI 的詳細信息，請參閱 Microsoft Windows 管理規(guī)范：背景和概述，網址為 (http://msdn.microsoft.com/library/default.asp?URL=/library/backgrnd/html/wmixwdm.htm)。

  Set Services = GetObject("WINMGMTS:{impersonationLevel=impersonate,(Security)}!"& AdminServer & "\ROOT\CIMV2")
  Set SecDescClass = Services.Get("Win32_SecurityDescriptor")
  Set SecDesc = SecDescClass.SpawnInstance_()
  Set Trustee = Services.Get("Win32_Trustee").SpawnInstance_
  Trustee.Domain = Null
  Trustee.Name = "EVERYONE"
  Trustee.Properties_.Item("SID") = Array(1，1，0，0，0，0，0，1，0，0，0，0)
  Set ACE = Services.Get("Win32_Ace").SpawnInstance_
  ACE.Properties_.Item("AccessMask") = 2032127
  ACE.Properties_.Item("AceFlags") = 3
  ACE.Properties_.Item("AceType") = 0
  ACE.Properties_.Item("Trustee") = Trustee
  SecDesc.Properties_.Item("DACL") = Array(ACE)
  Set Share = Services.Get("Win32_Share")
  Set InParam = Share.Methods_("Create").InParameters.SpawnInstance_()
  InParam.Properties_.Item("Access") = SecDesc
  InParam.Properties_.Item("Description") = "Public Share"
  InParam.Properties_.Item("Name") = ShareName
  InParam.Properties_.Item("Path") = FolderName
  InParam.Properties_.Item("Type") = 0
  Share.ExecMethod_("Create"，InParam)

運行已完成的腳本

本文檔中的示例包含一個完整的可執(zhí)行腳本，它具有上述所有功能。請參閱 WSH 網絡管理員示例腳本。

在運行該腳本前，要確保所有遠程計算機都配置正確以便運行遠程腳本。這是通過服務器上的 Poledit.exe 實現的。有關詳細信息，請參閱設置遠程 WSH。

運行遠程 WSH 時，該腳本被復制到遠程計算機上。驗證了遠程計算機的安全設置并成功復制腳本后，就會返回成功或失敗的消息。如果成功，就會在遠程計算機上執(zhí)行腳本。有關運行遠程 WSH 腳本的詳細信息，請參閱遠程運行腳本。

請參閱

設置遠程 WSH | 訪問網絡 | 遠程運行腳本