快捷導(dǎo)航

AndroidStudio Gradle第三依賴統(tǒng)一管理的實(shí)現(xiàn)方法

更新時(shí)間：2017年09月03日 13:39:20 作者：星空武哥

這篇文章主要介紹了AndroidStudio Gradle第三依賴統(tǒng)一管理的實(shí)現(xiàn)方法,需要的朋友可以參考下

AndroidStudio由于使用了gradle的進(jìn)行項(xiàng)目構(gòu)建，使我們開(kāi)發(fā)app方便很多，今天我就給大家列出幾點(diǎn)是用gradle的方便之處。

一、AndroidStudio Gradle第三依賴統(tǒng)一管理
二、AndroidStudio Gradle基于友盟的多渠道打包
三、AndroidStudio安全管理簽名文件keystroe和簽名密碼

這三篇文章很好的講解了gradle的在打包和項(xiàng)目依賴管理的優(yōu)點(diǎn)，大家可以參考一下，來(lái)提高自己的開(kāi)發(fā)效率，增強(qiáng)簽名文件的安全性。

在很多時(shí)候我們使用AndroidStudio開(kāi)發(fā)安卓App的時(shí)候都會(huì)引入第三方的庫(kù)，在一個(gè)project下我們可以有很多的module，每一個(gè)module就是一個(gè)app，但是每個(gè)module在進(jìn)行第依賴第三方的時(shí)候，有可能依賴第三方的版本不同，記住每次使用的版本號(hào)也不太可能，所以統(tǒng)一管理第三方依賴就尤其的重要。

我們可以將依賴的第三方集中放入到一個(gè)gradle中，然后在需要使用的的module中將其引入即可，這樣很方便的進(jìn)行的了不同版本的管理了。

首先我們?cè)趐roject下新建一個(gè)叫“config.gradle”的文件（名字隨便起），然后將要的所有第三方依賴庫(kù)進(jìn)行配置。

ext {
 
 android = [
   compileSdkVersion: 23,
   buildToolsVersion: "24.0.2",
   minSdkVersion : 15,
   targetSdkVersion : 23,
   versionCode  : 1,
   versionName  : "1.0"
 ]

 dependVersion = [
   support: "23.4.0"
 ]

 dependencies = [
   // ------------- Android -------------
   supportV4   : "com.android.support:support-v4:${dependVersion.support}",
   appcompatV7   : "com.android.support:appcompat-v7:${dependVersion.support}",
   design    : "com.android.support:design:${dependVersion.support}",
   junit    : "junit:junit:4.12",
   //------------- 測(cè)試 -------------
   espresso    : "com.android.support.test.espresso:espresso-core:2.2.2",

   // ------------- 網(wǎng)絡(luò)請(qǐng)求 -------------
   okhttp    : 'com.squareup.okhttp3:okhttp:3.3.1',
   retrofit    : 'com.squareup.retrofit2:retrofit:2.1.0',

   // ------------- 圖片加載 -------------
   fresco    : 'com.facebook.fresco:fresco:0.11.0',
   animatedGif   : 'com.facebook.fresco:animated-gif:0.12.0',
   picasso    : 'com.squareup.picasso:picasso:2.5.2',
   photoView   : 'com.github.chrisbanes:PhotoView:1.3.1',

   // ------------- RxAndroid -------------
   rxAndroid   : 'io.reactivex:rxandroid:1.2.1',
   rxJava    : 'io.reactivex:rxjava:1.2.2',

   // ------------- json解析 -------------
   fastJson    : 'com.alibaba:fastjson:1.1.54.android',
   gson     : 'com.google.code.gson:gson:2.8.0',

   // ------------- log打印工具 -------------
   logger    : 'com.orhanobut:logger:1.15',

   greendao    : 'org.greenrobot:greendao:3.2.0',

   // ------------- ButterKnife -------------
   butterknife   : 'com.jakewharton:butterknife:8.4.0',
   butterknifeCompiler : 'com.jakewharton:butterknife-compiler:8.4.0',

   // ------------- LeakCanary -------------
   leakcanaryAndroid : 'com.squareup.leakcanary:leakcanary-android:1.5',
   leakcanaryAndroidNoOp: 'com.squareup.leakcanary:leakcanary-android-no-op:1.5',
 ]
}

這樣我們就配置好了所有的依賴庫(kù)了，接下來(lái)就是要需要的依賴庫(kù)引入到我們的module中了。
1、在我們的project中的build.gradle中添加

apply from: "config.gradle"

2、在我們的module的build.gradle中引入
這是引入之前的gradle

apply plugin: 'com.android.application'
android {
 compileSdkVersion 23
 buildToolsVersion "24.0.2"

 defaultConfig {
  applicationId "com.bandeng.bandeng"
  minSdkVersion 15
  targetSdkVersion 23
  versionCode 1
  versionName "1.0"
  testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
 }
 buildTypes {
  release {
   minifyEnabled false
   proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
  }
 }
}
dependencies {
	compile fileTree(dir: 'libs', include: ['*.jar'])
 androidTestCompile("com.android.support.test.espresso:espresso-core:2.2.2", {
  exclude group: 'com.android.support', module: 'support-annotations'
 })
 compile "com.android.support:appcompat-v7:23.4.0"
 testCompile "junit:junit:4.12"
 compile "com.android.support:design:23.4.0"
}

改造之后的gradle

apply plugin: 'com.android.application'

android {
 compileSdkVersion rootProject.ext.android.compileSdkVersion
 buildToolsVersion rootProject.ext.android.buildToolsVersion

 defaultConfig {
  applicationId "com.bandeng.bandeng"
  minSdkVersion rootProject.ext.android.minSdkVersion
  targetSdkVersion rootProject.ext.android.targetSdkVersion
  versionCode rootProject.ext.android.versionCode
  versionName rootProject.ext.android.versionName
  testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
 }
 buildTypes {
  release {
   minifyEnabled false
   proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
  }
 }
}
dependencies {
 compile fileTree(dir: 'libs', include: ['*.jar'])
 androidTestCompile(rootProject.ext.dependencies.espresso, {
  exclude group: 'com.android.support', module: 'support-annotations'
 })
 compile rootProject.ext.dependencies.appcompatV7
 testCompile rootProject.ext.dependencies.junit
 compile rootProject.ext.dependencies.design
 // 網(wǎng)絡(luò)請(qǐng)求
 compile rootProject.ext.dependencies.okhttp
 compile rootProject.ext.dependencies.retrofit
 // 圖片加載
 compile rootProject.ext.dependencies.picasso
	// RxJava
 compile rootProject.ext.dependencies.rxAndroid
 compile rootProject.ext.dependencies.rxJava
 // json解析
 compile rootProject.ext.dependencies.gson
 // log打印工具
 compile rootProject.ext.dependencies.logger
}

這樣是不是很方便的管理依賴的第三方了。

您可能感興趣的文章: