欧美bbbwbbbw肥妇,免费乱码人妻系列日韩,一级黄片

Unity Shader模擬玻璃效果

 更新時間:2020年05月06日 08:38:25   作者:Zok93  
這篇文章主要為大家詳細(xì)介紹了Unity Shader模擬玻璃效果,文中示例代碼介紹的非常詳細(xì),具有一定的參考價值,感興趣的小伙伴們可以參考一下

本文實例為大家分享了Unity Shader實現(xiàn)玻璃效果的具體代碼,供大家參考,具體內(nèi)容如下

Shader "Glass Refraction" {
  Properties {
    _MainTex ("Main Tex", 2D) = "white" {}
    _BumpMap ("Normal Map", 2D) = "bump" {}
    _Cubemap ("Environment Cubemap", Cube) = "_Skybox" {}
    _Distortion ("Distortion", Range(0, 100)) = 10
    _RefractAmount ("Refract Amount", Range(0.0, 1.0)) = 1.0
  }
  SubShader {
    // 1.隊列設(shè)置成透明的可以保證渲染該物體的時候,其他所有不透明的物體都已經(jīng)被渲染到屏幕上了
    //  這樣GrabPass保存屏幕圖像的時候才能完整
    // 2.渲染類型設(shè)置為不透明是為了使用著色器替換的時候,物體可以在被需要時正確的渲染
    Tags { "Queue"="Transparent" "RenderType"="Opaque" }

    // 抓取屏幕圖像并保存到紋理 _RefractionTex 中
    GrabPass { "_RefractionTex" }

    Pass {   
      CGPROGRAM

      #pragma vertex vert
      #pragma fragment frag

      #include "UnityCG.cginc"

      sampler2D _MainTex;
      float4 _MainTex_ST;
      sampler2D _BumpMap;
      float4 _BumpMap_ST;
      samplerCUBE _Cubemap;
      float _Distortion;
      fixed _RefractAmount;
      sampler2D _RefractionTex;
      // 可以得到系統(tǒng)保存的紋素的尺寸大小 1/256,1/512
      // 對屏幕圖像坐標(biāo)采樣進(jìn)行偏移的時候需要使用該變量
      float4 _RefractionTex_TexelSize;

      struct a2v {
        float4 vertex : POSITION;
        float3 normal : NORMAL;
        float4 tangent : TANGENT; 
        float2 texcoord: TEXCOORD0;
      };

      struct v2f {
        float4 pos : SV_POSITION;
        float4 scrPos : TEXCOORD0;
        float4 uv : TEXCOORD1;
        float4 TtoW0 : TEXCOORD2; 
        float4 TtoW1 : TEXCOORD3; 
        float4 TtoW2 : TEXCOORD4; 
      };

      v2f vert (a2v v) {
        v2f o;
        o.pos = mul(UNITY_MATRIX_MVP, v.vertex);

        // 得到對應(yīng)被抓取的屏幕圖像的采樣坐標(biāo)
        o.scrPos = ComputeGrabScreenPos(o.pos);

        // 原圖和法線貼圖公用同一套UV坐標(biāo),進(jìn)行紋理偏移縮放設(shè)置
        o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
        o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);

        // 世界方向
        float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz; 

        // 法線世界方向
        fixed3 worldNormal = UnityObjectToWorldNormal(v.normal); 

        // 切線世界方向
        fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz); 

        // 世界副切線方向
        fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;

        // 定義:切線空間到世界空間的變換矩陣
        // 所有的TBN都從切線空間轉(zhuǎn)換到了世界空間
        o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x); 
        o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y); 
        o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z); 

        return o;
      }

      fixed4 frag (v2f i) : SV_Target {    
        // 世界空間
        float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);

        // 世界空間下的觀察方向
        fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(worldPos));

        // 對法線貼圖進(jìn)行采樣,并使用UnpackNormal解壓*2-1,但實際上法線貼圖在切線空間下
        // 所以需要將bump從切線空間轉(zhuǎn)換到世界空間
        fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw)); 

        // 對采樣坐標(biāo)進(jìn)行偏移
        float2 offset = bump.xy * _Distortion * _RefractionTex_TexelSize.xy;
        i.scrPos.xy = offset * i.scrPos.z + i.scrPos.xy;

        // 對屏幕紋理進(jìn)行采樣
        fixed3 refrCol = tex2D(_RefractionTex, i.scrPos.xy/i.scrPos.w).rgb;

        // 將bump從切線空間轉(zhuǎn)換到世界空間
        // TtoW0的xyz:T的X,B的X,N的X
        // 用點積得到一個常量
        bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));

        // 用法線貼圖求反射方向
        fixed3 reflDir = reflect(-worldViewDir, bump);

        // 主紋理采樣
        fixed4 texColor = tex2D(_MainTex, i.uv.xy);

        // 對_Cubemap進(jìn)行紋理采樣,使用反射方向
        fixed3 reflCol = texCUBE(_Cubemap, reflDir).rgb * texColor.rgb;

        // 反射顏色+折射顏色
        fixed3 finalColor = reflCol * (1 - _RefractAmount) + refrCol * _RefractAmount;

        return fixed4(finalColor, 1);
      }

      ENDCG
    }
  }

  FallBack "Diffuse"
}

以上就是本文的全部內(nèi)容,希望對大家的學(xué)習(xí)有所幫助,也希望大家多多支持腳本之家。

相關(guān)文章

  • C#?從字符串中分離文件路徑、文件名及擴(kuò)展名的操作

    C#?從字符串中分離文件路徑、文件名及擴(kuò)展名的操作

    在C#中,處理文件時經(jīng)常需要分離文件路徑、文件名和擴(kuò)展名,通過使用Microsoft.Win32命名空間和字符串處理方法如Substring、IndexOf()和LastIndexOf(),可以有效地獲取和操作這些信息,本文介紹C#?字符串中分離文件路徑,感興趣的朋友一起看看
    2024-09-09
  • c# RSA非對稱加解密及XML&PEM格式互換方案

    c# RSA非對稱加解密及XML&PEM格式互換方案

    這篇文章主要介紹了c# RSA非對稱加解密及XML&PEM格式互換方案,幫助大家更好的理解和使用c#,感興趣的朋友可以了解下
    2020-12-12
  • C#中IEnumerable接口介紹并實現(xiàn)自定義集合

    C#中IEnumerable接口介紹并實現(xiàn)自定義集合

    這篇文章介紹了C#中IEnumerable接口并實現(xiàn)自定義集合,文中通過示例代碼介紹的非常詳細(xì)。對大家的學(xué)習(xí)或工作具有一定的參考借鑒價值,需要的朋友可以參考下
    2022-04-04
  • 使用C#編寫簡單的圖形化的可發(fā)送附件的郵件客戶端程序

    使用C#編寫簡單的圖形化的可發(fā)送附件的郵件客戶端程序

    這篇文章主要介紹了使用C#編寫一個圖形化的可發(fā)送附件的郵件客戶端程序的方法,文中的示例同樣是基于支持smtp協(xié)議的郵件服務(wù)器,需要的朋友可以參考下
    2016-02-02
  • 使用aspose.word 第三方的插件實現(xiàn)導(dǎo)出word

    使用aspose.word 第三方的插件實現(xiàn)導(dǎo)出word

    本文給大家分享的是一個使用使用aspose.word 第三方的插件實現(xiàn)導(dǎo)出word的實例,十分的實用,有需要的小伙伴可以參考下。
    2015-06-06
  • c# 實現(xiàn)輪詢算法實例代碼

    c# 實現(xiàn)輪詢算法實例代碼

    這篇文章主要介紹了c# 實現(xiàn)輪詢算法實例代碼的相關(guān)資料,這里附有實例代碼,具有一定的參考價值,需要的朋友可以參考下
    2016-12-12
  • c#異步操作async?await狀態(tài)機(jī)的總結(jié)(推薦)

    c#異步操作async?await狀態(tài)機(jī)的總結(jié)(推薦)

    這篇文章主要介紹了c#異步操作async?await狀態(tài)機(jī)的總結(jié),關(guān)于async和await每個人都有自己的理解,甚至關(guān)于異步和同步亦或者關(guān)于異步和多線程每個人也都有自己的理解,本文通過實例代碼詳細(xì)講解,需要的朋友可以參考下
    2023-02-02
  • unity3d調(diào)用手機(jī)或電腦攝像頭

    unity3d調(diào)用手機(jī)或電腦攝像頭

    這個是在網(wǎng)上看到的,經(jīng)測試可以在電腦上運行,確實調(diào)用了本地攝像頭。有需要的小伙伴可以參考下。
    2015-03-03
  • 基于WPF繪制一個點贊大拇指動畫

    基于WPF繪制一個點贊大拇指動畫

    這篇文章主要為大家詳細(xì)介紹了WPF實現(xiàn)繪制一個點贊大拇指動畫,文中的示例代碼講解詳細(xì),對我們學(xué)習(xí)或工作有一定幫助,感興趣的小伙伴可以了解一下
    2023-02-02
  • Unity UGUI實現(xiàn)卡片橢圓方向滾動

    Unity UGUI實現(xiàn)卡片橢圓方向滾動

    這篇文章主要為大家詳細(xì)介紹了UGUI實現(xiàn)卡片橢圓方向滾動效果,文中示例代碼介紹的非常詳細(xì),具有一定的參考價值,感興趣的小伙伴們可以參考一下
    2019-03-03

最新評論