::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: chm文件反編譯器 V1.3
:: code by namejm 2007.12.27～2010.4.9 bbs.bathome.net CMD@XP
::
:: 功能：
:: 　　單個/批量反編譯chm文件，并保持資源的原始結(jié)構(gòu)。
:: 使用方式有兩種：
::   ① 把單個或多個文件直接拖放到本程序。
::   ② 直接雙擊運(yùn)行。此時處理的是當(dāng)前目錄下所有以.chm為后綴的文件
:: 執(zhí)行過程及處理效果：
:: 　　因?yàn)?hh -decompile 語句不能使用引號，所以，先把原始資源釋放到
:: 短文件名格式的文件夾中，釋放完畢后再改名；
:: 　　兩種執(zhí)行方式都有簡單的容錯處理；反編譯后的資源放在單獨(dú)的文件夾
:: 中，此文件夾位于當(dāng)前目錄，并以chm文件名命名。
::　　無法識別不以.chm為后綴名的chm文件，但是可以識別以.chm為后綴名
::的其他文件（貌似有點(diǎn)拗口^_^）
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo off
set TT=chm文件反編譯器 1.3
echo.&echo.&echo 　　　　正在反編譯CHM文件，請稍候...
cd /d "%~dp0"
:: 以拖動文件到批處理文件上的方式運(yùn)行批處理時，%cd% 的值將會強(qiáng)制轉(zhuǎn)換為
:: %homepath%，因此，上一條語句非常關(guān)鍵！
set "destination=chm文件反編譯結(jié)果"
for /f "delims=" %%i in ("%destination%") do set "destination_short=%%~sfi"
md "%destination%" 2>nul
del /a /f "%destination%\偽chm文件列表.txt" 2>nul
if "%~1"=="" goto All

:Some
set str=%*
set "str=%str:"=%"
set "str= %str%"
call set "str=%%str: %~d1=" "%~d1%%"
for %%i in ("%str%") do (
  if not %%i=="" (
    title %TT%-正在處理"%%~nxi"
    if /i not "%%~xi"==".chm" (
      echo.&echo 　　　　"%%~nxi"不是chm文件
      echo.&echo 　　　　請按任意鍵繼續(xù)...
      pause>nul
      cls
      echo.&echo.&echo 　　　　正在反編譯CHM文件，請稍候...
    ) else (
      rd /q /s "%%~ni" 2>nul
      hh -decompile %destination_short%\%%~sni %%~sfi
      if not exist "%destination%\%%~sni" (
        echo "%%~nxi">>"%destination%\偽chm文件列表.txt"
      ) else (
        ren "%destination%\%%~sni" "%%~ni" 2>nul
      )
    )
  )
)
exit

:All
for /f "delims=" %%i in ('dir /a-d /b *.chm 2^>nul') do (
  title %TT%-正在處理"%%~nxi"
  rd /q /s "%destination%\%%~ni" 2>nul
  hh -decompile %destination_short%\%%~sni %%~sfi
  if not exist "%destination%\%%~sni" (
    echo "%%~nxi">>"%destination%\偽chm文件列表.txt"
  ) else (
    ren "%destination%\%%~sni" "%%~ni" 2>nul
  ) 
)