'=============================================================
'=       Copyright (c) 2010 貓七(QQ:77068320)     =
'=         All rights reserverd.          =
'=============================================================
'=        IIS日志分析系統(tǒng) v_1.10.0828         =
'=   使用說明：http://www.miaoqiyuan.cn/p/iis-log-tools  =
'=   作者博客：http://www.miaoqiyuan.cn          =
'=   版權(quán)聲明：本代碼供站長(zhǎng)免費(fèi)使用，傳播請(qǐng)保留版權(quán)信息  =
'=============================================================
'=  程序簡(jiǎn)介：在網(wǎng)上找了很多IIS日志分析工具，功能簡(jiǎn)單，只能 =
'= 分析爬蟲來訪次數(shù)。有時(shí)候我們小站長(zhǎng)也想分析下廣告點(diǎn)擊情況 =
'= ，這時(shí)候市面上的IIS統(tǒng)計(jì)工具就無能為力了。耗時(shí)一晚上寫出來 =
'= 分享給大家，同時(shí)申請(qǐng)落伍，請(qǐng)大家?guī)晚敗?         =
'=  申請(qǐng)地址：http://www.im286.com/thread-5021543-1-1.html =
'=============================================================
'= 文件：log.vbs                      =
'= 功能：IIS日志分析，懂程序的朋友可擴(kuò)展，功能不可限量   =
'=============================================================
 
dbpath = "D:\log"         '日志文件所在目錄
tblna = "test.txt"         '日志文件名，如果修改請(qǐng)同時(shí)修改 Schema.ini 中相關(guān)節(jié)點(diǎn)
 
function getuag(str)
 if instr(str,"+MSIE+7.0;")>0 then
  getuag = "Internet Explore 7.0"
 elseif instr(str,"+MSIE+8.0;")>0 then
  getuag = "Internet Explore 8.0"
 elseif instr(str,"+MSIE+6.0;")>0 then
  getuag = "Internet Explore 6.0"
 elseif instr(str,"MSIE")>0 then
  getuag = "Internet Explore(Other)"
 elseif instr(str,"curl")>0 then
  getuag = "CUrl"
 else
  getuag = str
 end if
end function
 
wscript.echo string(60,"=")
wscript.echo "     IIS日志分析工具 By 苗啟源(MiaoQiyuan.cn)"
wscript.echo string(60,"=")
 
set conn = createobject("ADODB.Connection")
conn.open "provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & dbpath & ";Extended Properties=""text;HDR=YES;FMT=Delimited;"""
 
set rs = createobject("ADODB.Recordset")
 
'統(tǒng)計(jì) 鏈接訪問次數(shù)
statime = timer()
rs.open "select [cs-uri-stem],count([c-ip]) from [" & tblna & "] group by [cs-uri-stem]",conn,1,1
ga = rs.getrows()
rs.close
wscript.echo " = 訪問次數(shù) = | = 獨(dú)立訪客 = | = 訪問路徑 = "
wscript.echo string(60,"-")
for i = 0 to ubound(ga,2)
 rsid = rsid + 1
 tme = ga(1,i)
 uri = ga(0,i)
  
 '不支持 COUNT DISTINCT 郁悶，使用笨拙的方法
 rs.open "select DISTINCT [c-ip] from [" & tblna & "] where [cs-uri-stem]='" & uri & "'",conn,1,1
 aip = rs.recordcount
 rs.close
  
 wscript.echo string(10 - len(tme)," ") & tme & "  | " & string(8 - len(aip)," ") & aip & "   | " & uri
next
wscript.echo string(60,"-")
wscript.echo "  統(tǒng)計(jì)：" & rsid & "條記錄 查詢用時(shí)：" & formatnumber((timer() - statime) * 1000,3) & "毫秒"
wscript.echo string(60,"-") & vbCrlf
 
 
'統(tǒng)計(jì) 訪問詳情
for i = 0 to ubound(ga,2)
 rsid = 0
 uri = ga(0,i)
 wscript.echo string(60,"=")
 wscript.echo "     訪問詳情：" & uri
 wscript.echo string(60,"=")
 statime = timer()
 wscript.echo " = 編號(hào) = | = IP地址 = | = 瀏覽器類型 = "
 rs.open "select DISTINCT [c-ip],[cs(User-Agent)] from [" & tblna & "] where [cs-uri-stem]='" & uri & "'",conn,1,1
 do while not rs.eof
  rsid = rsid + 1
  'IP 自動(dòng)變成了數(shù)字，還沒有找到解決方法
  cip = rs(0)
  uag = getuag(rs(1))
  wscript.echo string(8 - len(rsid)," ") & rsid & " | " & string(8 - len(cip)," ") & cip & " | " & uag
  rs.movenext
 loop
 rs.close
 wscript.echo string(60,"-")
 wscript.echo "  統(tǒng)計(jì)：" & rsid & "條記錄 查詢用時(shí)：" & formatnumber((timer() - statime) * 1000,3) & "毫秒"
 wscript.echo string(60,"-") & vbCrlf
next