快捷導(dǎo)航

在VBS中定義字節(jié)數(shù)組Byte()介紹

更新時間：2013年01月14日 00:45:50 作者：

在VBS中有辦法定義字節(jié)數(shù)組么？就是字節(jié)子類型數(shù)組（VarType是8209的那種）注意不是VB

晚上在 QQ 上看到昵稱為“亂碼”的好友回答了搜搜問問里一個問題：

在VBS中有辦法定義字節(jié)數(shù)組么？
在VBS中有辦法定義字節(jié)數(shù)組么？就是字節(jié)子類型數(shù)組（VarType是8209的那種）注意不是VB！

但是回答實在是不堪入目，連別人問什么都沒搞懂，而且那人居然還滿意，真不知道他在想什么。

閑來沒事，我來簡單回答一下。首先要搞清楚別人在問什么，VBS 是弱類型腳本語言，只有一種數(shù)據(jù)類型，稱為 Variant，但是 Variant 可以進(jìn)一步分為幾種子類型，這里不展開，詳見《VBScript 數(shù)據(jù)類型》。所謂字節(jié)子類型數(shù)組（VarType是8209的那種），就是子類型為 Byte 的數(shù)組（vbByte + vbArray = 17 + 8192 = 8209）。

例如，Msxml2.XMLHTTP 對象的 responseBody 屬性返回的就是字節(jié)數(shù)組：

復(fù)制代碼代碼如下:

 
'Author: Demon 
'Website: http://demon.tw 
'Date: 2012/2/22 
Dim http, res 
Set http = CreateObject("Msxml2.XMLHTTP") 
http.open "GET", "http://demon.tw", False 
http.send 
res = http.responseBody 
WScript.Echo VarType(res), TypeName(res) 

再例如，ADODB.Stream 對象的 Read 方法返回的也是字節(jié)數(shù)組：

復(fù)制代碼代碼如下:

 
'Author: Demon 
'Website: http://demon.tw 
'Date: 2012/2/22 
Dim ado, data 
Set ado = CreateObject("ADODB.Stream") 
ado.Type = 1 
ado.Open 
ado.LoadFromFile "demon.tw" 
data = ado.Read 
WScript.Echo VarType(data), TypeName(data) 

那么如何在 VBS 中定義一個字節(jié)數(shù)組呢？有人說那還不簡單，用 CByte 函數(shù)強(qiáng)制轉(zhuǎn)換一下不就行了？真的是這樣么，寫個簡單的例子測試一下：

復(fù)制代碼代碼如下:

 
'Author: Demon 
'Website: http://demon.tw 
'Date: 2012/2/22 
Dim a(9), i 
For i = 0 To 9 
a(i) = CByte(i) 
Next 
WScript.Echo VarType(a), TypeName(a) 

'輸出 8204 Variant()程序輸出 8204 Variant()，很可惜，這不是我們想要的。

那么正確的方法是什么呢？其實在《用VBS讀寫二進(jìn)制文件的另一種方法》中出現(xiàn)過，使用 Msxml2.DOMDocument 對象：

復(fù)制代碼代碼如下:

 
'Author: Demon 
'Website: http://demon.tw 
'Date: 2012/2/22 
Dim xmldoc, node, bytes 
Set xmldoc = CreateObject("Msxml2.DOMDocument") 
Set node = xmldoc.CreateElement("binary") 
node.DataType = "bin.hex" 
'demon.tw 的十六進(jìn)制值為 
'64 65 6D 6F 6E 2E 74 77 
node.Text = "64656D6F6E2E7477" 
bytes = node.NodeTypedValue 
WScript.Echo VarType(bytes), TypeName(bytes) 