:::::::批量修改文件名.bat:::::::
@echo off
title 批量修改文件名
setlocal EnableDelayedExpansion
:: 啟用延遲變量擴充

:GetPath
set zpath=%CD%
:: 對變量進行初始化，防止用戶不輸入而直接跳過。其中%CD%表示當(dāng)前路徑
set /p zpath=請輸入目標(biāo)文件所在的路徑：
if %zpath:~0,1%%zpath:~-1%=="" set zpath=%zpath:~1,-1%
:: 檢查變量 zpath 的第一個和最后一個字符是否為 "" ，是的話就去掉
if not exist "%zpath%" goto :GetPath
:: 如果 zpath 值的路徑不存在，就得跳轉(zhuǎn)回去，要求重新輸入

:GetPrefix
set prefix=未命名
set /p prefix=請輸入文件名前綴(不能包含以下字符\/:*?"<>|)：
for /f "delims=\/:*?<>| tokens=2" %%i in ("z%prefix%z") do goto :GetPrefix
:: 這里對變量 perfix 進行檢查，發(fā)現(xiàn)有非法符號便跳轉(zhuǎn)到 :GetPrefix
:: 事實上，這里并沒有對雙引號 " 進行檢測，因為雙引號無法在此被轉(zhuǎn)義為可用的分隔符
:: 即使是在這個程序里，不正確地使用雙引號也會引起程序異常而退出。
:: 因此，想把它做的非常人性化并不是一件容易的事情

:GetExt
set ext=.*
set /p ext=請輸入文件的擴展名(不輸入則表示所有類型)：
if not "%ext:~0,1%"=="." set ext=.%ext%
:: 檢查變量 ext 的第一個是否為句點 . ，不是的話就加上
:: 建議這里對變量 ext 也檢查一下，發(fā)現(xiàn)有除*外的非法符號便跳轉(zhuǎn)到 :GetExt

set answer=N
echo.
echo 您試圖將 %zpath%\ 里的所有 %ext% 類型的文件以 %prefix% 為前綴名進行批量改名，是否繼續(xù)？
set /p answer=繼續(xù)請輸入 Y ，輸入其它鍵放棄...
if "%answer%"=="Y" goto :ReadyToRename
if "%answer%"=="y" goto :ReadyToRename

echo 放棄文件改名，按任意鍵退出... & goto :PauseThenQuit

:ReadyToRename

set /a num=0
echo.

if "%ext%"==".*" (
  for %%i in ("%zpath%\*%ext%") do (
    set /a num+=1
    ren "%%i" "%prefix%!num!%%~xi" || echo 文件 %%i 改名失敗 && set /a num-=1
  )
) else (
  for %%i in ("%zpath%\*%ext%") do (
    set /a num+=1
    ren "%%i" "%prefix%!num!%ext%" || echo 文件 %%i 改名失敗 && set /a num-=1
  )
)

if %num%==0 echo %zpath%\ 里未發(fā)現(xiàn)任何文件。按任意鍵退出... & goto :PauseThenQuit

echo 文件改名完成，按任意鍵退出...

:PauseThenQuit
pause>nul
::::::::::::::::::::::::::::::::