@echo off 
title 自動關(guān)機(jī)程序 作者:青劍 
rem 這里改成你的名字好了 
color 17 
rem 如果你不喜歡命令行默認(rèn)的黑底白字模式,可以用color命令進(jìn)行更改,上面"17"代表藍(lán)底白字. 
:start 
echo. 
echo. 
echo  請選擇要進(jìn)行的操作，然后按回車： 
echo. 
echo           1. 定時關(guān)機(jī) 
echo           2. 倒計(jì)時關(guān)機(jī) 
echo           3. 刪除定時關(guān)機(jī)任務(wù) 
echo           4. 查看定時關(guān)機(jī)任務(wù)狀態(tài) 
echo           5. 注銷 
echo           6. 退出 
echo.  
:set  
SET a= 
SET /P a=選擇: 
rem 設(shè)定變量"a"為用戶輸入的字符 
IF NOT '%a%'=='' SET a=%a:~0,1% 
ECHO. 
IF /I '%a%'=='1' goto 1 
IF /I '%a%'=='2' goto 2 
IF /I '%a%'=='3' goto 3 
IF /I '%a%'=='4' goto 4 
IF /I '%a%'=='5' goto 5 
IF /I '%a%'=='6' goto 6 
rem 如果輸入的字符不是1-6,將返回重新輸入 
echo %a%       選擇無效，請重新輸入： 
echo. 
goto set 
:1 
echo 請輸入關(guān)機(jī)時間,(如12:00:00) 
set shutdowntime= 
set /p shutdowntime= 
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul 
IF not errorlevel 1 goto ok 
rem 如果輸入正確,就執(zhí)行:ok后面的語句 
echo %shutdowntime% 不是標(biāo)準(zhǔn)的時間格式,請重新輸入 
echo. 
goto 1 
:ok 
echo. 
echo 設(shè)定完畢! 按任意鍵繼續(xù)... 
pause >nul 
cls 
goto start 
:2 
echo 您想要多少秒后關(guān)機(jī) 
echo (若設(shè)定后要取消,單擊"確定"后按Ctrl+C鍵兩次) 
set timed= 
set /p timed=輸入: 
tsshutdn %timed% /delay:0  /powerdown >nul 
IF not errorlevel 1 goto ok 
echo %timed% 是無效的關(guān)機(jī)時間,請重新輸入 
echo. 
goto 2 
:3 
at /del /y 
echo 定時關(guān)機(jī)任務(wù)已取消,按任意鍵繼續(xù)... 
pause >nul 
cls 
goto start 
:4 
at 
echo 按任意鍵繼續(xù)... 
pause >nul 
cls 
goto start 
:5 
logoff 
:6 
exit