@echo off
rem South China Agriculture University
rem version 0.01
rem 使用介紹
rem 功能:試圖設(shè)置自動連接校內(nèi)Windows Update服務(wù)器
rem 先進行服務(wù)檢查，沒有安裝服務(wù)的機器先安裝服務(wù)，重啟動后再修改設(shè)置
rem History
rem 2004-03-17 0.01b 全校公測
echo [INFO] For Windows 2000,Windows XP,Windows 2003 only.
echo [INFO] 只在Windows 2000,Windows XP,Windows 2003 上適用
echo [INFO] For Normal user only (computer that runs every day)
set Server=0
rem Server=1
pause
cls
rem 創(chuàng)建臨時文件夾
set mhnet=%temp%\mhnet
rmdir /S /Q %mhnet% 2>NUL 1>NUL
mkdir %mhnet%
rem 系統(tǒng)語言環(huán)境判斷
reg query HKLM\SYSTEM\CurrentControlSet\Control\Nls\Language >%mhnet%\Language.log
find "Default" %mhnet%\Language.log |find "0804" >NUL
IF NOT ERRORLEVEL 1 (
set Language=Chinese
) else (
set Language=English
)
if %Language%==Chinese (
echo [INFO] 本程序?qū)樵O(shè)置校內(nèi) Windows Automatic Updates 服務(wù)
) else (
echo [INFO] This will setup SCAU Windows Automatic Updates Services
)
start readme.txt
rem 檢查配套文件完整性
call :AllFiles
rem 檢查屬于NT系列
call :CheckSystem
rem 檢查擁有管理員權(quán)限
call :CheckAdmin
rem 檢查Automatic Updates服務(wù)是否正常安裝
call :CheckService
call :SCAURegImport
if %Language%==Chinese (
echo [INFO] 程序討論，歡迎到 bbs.scau.edu.cn NC板
echo [INFO] 程序結(jié)束
) else (
echo [INFO] We welcome you to press your opinion on bbs.scau board:NC
echo [INFO] Program Exit
)
pause
set mhnet=
set patchfile=
set downloadurl=
goto :eof
exit
:ends
rem 主函數(shù)結(jié)束
rem *************************
rem *************************
rem 導(dǎo)入:SCAURegImport
rem *************************
rem *************************
:SCAURegImport
ECHO [INFO] 備份注冊表(Backup Reg) %temp%
pushd %temp%
set BakFile1=AutoUpdateBak1.reg
set BakFile2=AutoUpdateBak2.reg
if exist %BakFile1% (
ECHO [INFO] 已經(jīng)安裝了本補丁，按任意鍵刪除原有備份
PAUSE
delete %BakFile1% /f /q >NUL 2>NUL
delete %BakFile2% /f /q >NUL 2>NUL
)
popd
pushd %mhnet%
reg EXPORT "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" %BakFile1% 1>NUL
reg EXPORT "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" %BakFile2% 1>NUL
move %BakFile1% %temp% >NUL
move %BakFile2% %temp% >NUL
set BakFile1=
set BakFile2=
popd
ECHO [INFO] 正在停止WindowsUpdate服務(wù)(Stopping Update service)......
net stop wuauserv >NUL 2>NUL
ECHO [INFO] 正在修改注冊表操作(Modifying Registry)......
ECHO Y |reg DELETE "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /va /f >NUL
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate /v WUServer /t REG_SZ /d "http://sus.scau.edu.cn" /f >NUL
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate /v WUStatusServer /t REG_SZ /d "http://sus.scau.edu.cn" /f >NUL
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU /v NoAutoRebootWithLoggedOnUsers /t REG_DWORD /d 1 /f >NUL
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU /v NoAutoUpdate /t REG_DWORD /d 0 /f >NUL
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU /v RescheduleWaitTime /t REG_DWORD /d 1 /f >NUL
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU /v ScheduledInstallDay /t REG_DWORD /d 0 /f >NUL
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU /v UseWUServer /t REG_DWORD /d 1 /f >NUL
if %Server%==1 (
ECHO [INFO] Automatic Updates Service installed for server
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU /v AUOptions /t REG_DWORD /d 4 /f >NUL
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU /v ScheduledInstallTime /t REG_DWORD /d 11 /f >NUL
) else (
ECHO [INFO] Automatic Updates Service installed for non-server
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU /v AUOptions /t REG_DWORD /d 2 /f >NUL
reg add HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU /v ScheduledInstallTime /t REG_DWORD /d 12 /f >NUL
)
rem 服務(wù)自動啟動
ECHO [INFO] 設(shè)置服務(wù)為自動啟動(Set service to automatic start)
reg add HKLM\SYSTEM\CurrentControlSet\Services\wuauserv /v Start /t REG_DWORD /d 2 /f >NUL
reg add HKLM\SYSTEM\CurrentControlSet\Services\BITS /v Start /t REG_DWORD /d 2 /f >NUL
ECHO [INFO] 正在重新啟動WindowsUpdate服務(wù)(Starting Update Service)......
net start bits >NUL 2>NUL
net start wuauserv >NUL 2>NUL
goto :eof
rem *************************
rem *************************
rem 停止/刪除服務(wù)函數(shù)
rem *************************
rem *************************
:StopService
set SrvName=%1
net stop %SrvName% >NUL >NUL2
reg query HKLM\SYSTEM\CurrentControlSet\Services\\%SrvName% >NUL
if not errorlevel 1 (
reg delete HKLM\SYSTEM\CurrentControlSet\Services\\%SrvName% /f >NUL
) ELSE (
if %Language%==Chinese (
echo [FAIL] 系統(tǒng)服務(wù): %SrvName% *沒找到*
) else (
echo [FAIL] System Service: %SrvName% Not Found
)
)
goto :eof
rem *************************
rem *************************
rem 判斷是否NT系列系統(tǒng)，win9x系統(tǒng)則退出
rem *************************
rem *************************
:CheckSystem
if NOT %OS%==Windows_NT (
if %Language%==Chinese (
echo [INFO] 本程序?qū)橹形?英文版本的Win2000,WinXP,Win2003設(shè)計
echo [FAIL] Windows 95, Windows 98, Windows ME的用戶不必運行
echo [INFO] 程序退出。
) else (
echo [INFO] Design for Win2k,WinXP,Win2003 with Chinese or English version only.
echo [FAIL] Windows 95,Windows 98, Windows ME will not be troubled by this bug.
echo [INFO] Thank you for checking. Please deliver this to someone who need it.
)
pause
exit
) else (
if %Language%==Chinese (
echo [INFO] 用戶使用基于WindowsNT內(nèi)核的系統(tǒng),
) else (
echo [INFO] You are using a system based on WindowsNT kernel,
)
)
goto :eof
rem *************************
rem *************************
rem 判斷是否NT系列系統(tǒng)，win9x系統(tǒng)則退出
rem *************************
rem *************************
:CheckAdmin
net user "%username%" 1> %mhnet%\ifadmin.log
rem 如果不是系統(tǒng)管理員
find "*Administrators " %mhnet%\ifadmin.log >NUL
IF ERRORLEVEL 1 (
if %Language%==Chinese (
echo [FAIL] 用戶不是系統(tǒng)管理員組成員 ，不能執(zhí)行相應(yīng)程序
echo [INFO] 請更換有足夠權(quán)限的用戶重新運行本程序
) else (
echo [FAIL] This program require administrator right to continue
echo [INFO] Please switch user and try again
)
pause
exit
goto :eof
) else (
if %Language%==Chinese (
echo [INFO] 用戶屬于系統(tǒng)管理員組,
) else (
echo [INFO] You have got the right of administrator,
)
)
goto :eof
rem *************************
rem *************************
rem 先進行補丁檢查，沒有安裝補丁的機器先安裝補丁，重啟動后再查殺病毒
rem *************************
rem *************************
:CheckService
rem if %Language%==Chinese (
rem echo [INFO] 檢查 Automatic Updates
rem ) else (
rem echo [INFO] Checking Automatic Updates Service
rem )
rem 檢查服務(wù)的注冊表值
reg query "HKLM\SYSTEM\CurrentControlSet\Services" >%mhnet%\Services.log
find "wuauserv" %mhnet%\Services.log >NUL
IF ERRORLEVEL 1 (
rem 您的計算機未安裝Automatic updates服務(wù)
call :InstallService
pause
exit
rem 中止執(zhí)行
) ELSE (
rem if %Language%==Chinese (
rem echo [INFO] 注冊表檢查顯示您的系統(tǒng)已經(jīng)安裝了wuauserv服務(wù)。
rem ) else (
rem echo [INFO] reg reports that your system has wuauserv service installed
rem )
)
goto :eof
rem *************************
rem *************************
rem 清空注冊表某\Run值
rem *************************
rem *************************
:CleanRun
reg delete HKLM\Software\Microsoft\Windows\CurrentVersion\Run\\%1 /f >NUL
goto :eof
rem *************************
rem *************************
rem 停止不安全服務(wù)
rem *************************
rem *************************
:StopUnSafeSrv
rem net stop %1 >NUL
reg add HKLM\SYSTEM\CurrentControlSet\Services\\%1 /v Start /t REG_DWORD /d 0x3 /f >NUL
goto :eof
rem *************************
rem *************************
rem 導(dǎo)入正常注冊表的execute文件關(guān)聯(lián)
rem *************************
rem *************************
:Regdefault
reg import regdefault.reg >NUL
goto :eof
rem *************************
rem *************************
rem 安裝wuauserv包
rem *************************
rem *************************
:InstallService
rem reg query HKLM\SYSTEM\CurrentControlSet\Control\Nls\Language >%mhnet%\Language.log
rem 中文系統(tǒng)
find "InstallLanguage" %mhnet%\Language.log |find "0804" >NUL
IF NOT ERRORLEVEL 1 (CALL :CNService )
rem 英文系統(tǒng)
find "InstallLanguage" %mhnet%\Language.log |find "0409" >NUL
IF NOT ERRORLEVEL 1 (CALL :ENService )
rem 其他語言包，以上語言包雖用call調(diào)用，但不希望返回
if %Language%==Chinese (
echo [FAIL] 你并未使用中文/英文操作系統(tǒng)，
echo [INFO] 請記下下面顯示的InstallLanguage及Default的值,請到微軟網(wǎng)站下載相應(yīng)服務(wù)
echo [INFO] 程序退出
) else (
echo [FAIL] You are not using windows with Chinese/English language
echo [INFO] We suggest you download the service from microsoft website.
echo [INFO] Please write down the InstallLanguage & Default value for later use.
echo [INFO] program terminated
)
find "InstallLanguage" %mhnet%\Languate.log
start //www.microsoft.com/downloads/details.aspx?FamilyID=799432fb-c196-4f01-8cce-4f9ea58d6177&DisplayLang=en
rem 微軟服務(wù)安裝網(wǎng)頁
pause
exit
goto :eof
rem *************************
rem *************************
rem 中文服務(wù)包下載安裝
rem *************************
rem *************************
:CNService
set patchfile=WUAU22CHS.msi
set downloadurl=//sus.scau.edu.cn/%patchfile%
call :Download
start %mhnet%\%patchfile%
if %Language%==Chinese (
echo [INFO] 安裝好服務(wù)后重啟電腦，再運行本程序
) else (
echo [INFO] Restart your computer when Service installation is done. And run again.
)
pause
exit
goto :eof
rem *************************
rem *************************
rem 英文服務(wù)包下載安裝
rem *************************
rem *************************
:ENService
set patchfile=WUAU22ENU.msi
set downloadurl=//sus.scau.edu.cn/%patchfile%
call :Download
start %mhnet%\%patchfile%
if %Language%==Chinese (
echo [INFO] 安裝好服務(wù)后重啟電腦，再運行本程序
) else (
echo [INFO] Restart your computer when Service installation is done. And run again.
)
pause
exit
goto :eof
rem *************************
rem *************************
rem 檢查部分文件完整性
rem *************************
rem *************************
:AllFiles
if not exist reg.exe (
echo [WARN] reg.exe NOT FOUND
pause
exit
) else (
copy reg.exe %mhnet% /y >NUL
)
if not exist wget.exe (
echo [WARN] wget.exe NOT FOUND
pause
exit
) else (
copy wget.exe %mhnet% /y >NUL
)
goto :eof
rem *************************
rem *************************
rem 下載補丁，用%patchfile%傳入文件名
rem *************************
rem *************************
:Download
if %Language%==Chinese (
echo [INFO] 自動下載 %downloadurl%
) else (
echo [INFO] Downloading %downloadurl%
)
pushd %mhnet%
if exist %patchfile% (
del %patchfile% /f /q >NUL 2>NUL
)
wget %downloadurl%
IF NOT ERRORLEVEL 1 (
if %Language%==Chinese (
echo [INFO] 下載成功。
) else (
echo [INFO] Download Success
)
) else (
if %Language%==Chinese (
echo [FAIL] 下載失敗。程序退出
) else (
echo [FAIL] Download Failed. Terminated
)
pause
exit
)
popd
goto :eof
rem ----- this is the end of this batch file -------