%1?mshta?vbscript之管理員權限運行bat的解讀

更新時間：2024年07月09日 11:48:29 作者：重新開始的碼農

最近發(fā)現(xiàn)很多朋友咨詢%1?mshta?vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c?"^&chr(34)^&"%~0"^&chr(34)^&"?::","%cd%","runas",1)(window.close)&&exit的意思，這里就為大家簡單介紹一下

一、提取代碼

注意功能就是將當前bat的執(zhí)行提升為管理員，因為有些操作只有管理員才可以執(zhí)行，否則就會出現(xiàn)錯誤，為了方便用戶特將這句話寫到bat的開頭，利用vbs實現(xiàn)提取運行當前的bat文件

%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c "^&chr(34)^&"%~0"^&chr(34)^&" ::","%cd%","runas",1)(window.close)&&exit
cd %~dp0
%~d0
taskkill /im python.exe /f
taskkill /im java.exe /f
taskkill /im node.exe /f
taskkill /im npm.exe /f
python lanuch_python.py

或者

%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit cd /d "%~dp0"

二、資料

 批處理，%~d0 cd %~dp0 代表什么意思

批處理，%~d0 cd %~dp0 代表什么意思
 
~dp0 “d”為Drive的縮寫，即為驅動器，磁盤、“p”為Path縮寫，即為路徑，目錄
cd是轉到這個目錄，不過我覺得cd /d %~dp0 還好些

選項語法:

    ~0         - 刪除任何引號(")，擴充 %0
    %~f0        - 將 %0 擴充到一個完全合格的路徑名(“f”是file，即文件)
    %~d0        - 僅將 %0 擴充到一個驅動器號
    %~p0        - 僅將 %0 擴充到一個路徑
    %~n0        - 僅將 %0 擴充到一個文件名(“n”是name 文件名)
    %~x0        - 僅將 %0 擴充到一個文件擴展名
    %~s0        - 擴充的路徑只含有短名(“s”為Short，短的)
    %~a0        - 將 %0 擴充到文件的文件屬性(“a”為attribute，即屬性)
    %~t0        - 將 %0 擴充到文件的日期/時間(“t”time)
    %~z0        - 將 %0 擴充到文件的大小(Size 大小)
    %~PATH:0?查找列在路徑環(huán)境變量的目錄，并將
PATH:0 - 查找列在路徑環(huán)境變量的目錄，并將 %I 擴充
                  到找到的第一個驅動器號和路徑。
    %~ftza0     - 將 %0 擴充到類似輸出線路的 DIR

%0為當前批處理文件
如果0換成1為第一個文件，2為第2個

三、分析

1、“cd %~dp0”

分析：cd 到該腳本所在的目錄下。

2、“%~d0”

分析：僅將 %0 擴充到一個驅動器號

3、“%1”

分析：%1 指批處理文件名后加的以空格分隔的字符串

4、“%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c "^&chr(34)^&"%~0"^&chr(34)^&" ::","%cd%","runas",1)(window.close)&&exit”

分析：當需要在Windows中使用管理員身份運行cmd時，可以使用vbs來進行

5、"^&chr(34)^&"

分析：雙引號的ASCII碼

淺談批處理獲取管理員運行權限的幾種方法

很多用了Win10版本系統(tǒng)的人都會發(fā)現(xiàn)，Windows對程序的運行權限是控制得更加嚴格了，即使你將UAC控制放至最低，如果沒有特別賦予外來程序管理員運行權限的話，很多程序都會運行出錯，包括很多用于系統(tǒng)維護的批處理程序由于運行權限不夠都會導致出錯，最簡單的方法莫過于用右鍵點擊程序，然后選擇“以管理員身份運行”，對于那些需要經(jīng)常使用的程序，我們可以進入程序的屬性里面勾選上“以管理員身份運行”，這樣每次點擊它都會直接以管理員身份運行了。以上這些都是對單個程序的臨時解決措施。那么對于眾多的批處理程序，每次都用右鍵覺得很麻煩，又不可能到每個程序的屬性里面去設置一下，效率低下，那有沒有辦法讓批處理程序能夠自動獲取管理員運行權限呢，讓其直接雙擊即可實現(xiàn)正常運行，答案當然是有的。下面是我從網(wǎng)上找到的幾種提升批處理運行權限的方法，另外也有一些本人自己摸索出來的方法。

方法1：借用VBS腳本

%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit

方法2：借用VBS腳本

%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
exit /B

方法3：借用VBS腳本

echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
del /f /q "%temp%\getadmin.vbs" >nul
exit /B

方法4：借用第三方程序

nircmd elevate cmd /c "%0"
exit /B

方法5：runas命令

runas /noprofile /user:Administrator "%0"
exit /B

以上是批處理獲取管理員權限的5種方法，只要把這幾個命令放進批處理優(yōu)先執(zhí)行即可，當然還要加上判斷是否已經(jīng)獲取管理員權限的語句，否則批處理就會無限循環(huán)下去。判斷批處理是否已獲取管理員權限的方法，網(wǎng)上用的最多的是下面這句命令：

以方法1為例：

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (goto UACPrompt) else (goto UACAdmin)
:UACPrompt
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
:UACAdmin
echo 已獲取管理員權限

用cacls命令來判斷管理員權限固然不錯，但經(jīng)過實踐我發(fā)現(xiàn)cacls返回的errorlevel值不夠穩(wěn)定，經(jīng)常會變換出其他不可預知的錯誤碼，造成判斷有誤，導致批處理進入死循環(huán)。當然也有人采用能否往系統(tǒng)目錄（比如system32）寫入文件的方法來判斷，我覺得這些都不夠好，后來我發(fā)現(xiàn)使用bcdedit命令來判斷比較準確，一般情況下它只會返回兩個錯誤碼0和1，很少見到有其他值出現(xiàn)，目前它是我覺得用來判斷管理員權限最好的方法。

前3種方法是使用了VBS腳本，方法1最簡潔，一行代碼就搞定了，但我發(fā)現(xiàn)Win10系統(tǒng)似乎不支持短文件名，一旦文件路徑出現(xiàn)空格，該命令就會出錯；方法2也不賴，只有兩行代碼，在Win10系統(tǒng)能穩(wěn)定運行；方法3比較復雜，還會產(chǎn)生臨時文件，但也能在Win10系統(tǒng)穩(wěn)定運行；第4種方法使用了第三方程序，不會產(chǎn)生臨時文件，代碼也簡單，但你得先下載nircmd.exe這個工具；第5種方法采用了系統(tǒng)自帶的命令runas來實現(xiàn)，理論上是沒問題的，但實際上比較難實現(xiàn)，首先要求Administrator管理員賬戶必須已經(jīng)啟用，其次還必須設置有管理員密碼，否則都會得到拒絕的提示。

以上5種方法都可以提升批處理的運行權限，可根據(jù)具體情況選擇最合適的方法，我比較喜歡方法2，代碼簡潔，運行穩(wěn)定，不會產(chǎn)生臨時文件，其次方法4也不錯。如果您有更好的批處理提權方法，也可以跟大家一起分享！共同進步！

附：批處理獲取管理員權限完整代碼

@echo off
if exist "%SystemRoot%\SysWOW64" path %path%;%windir%\SysNative;%SystemRoot%\SysWOW64;%~dp0
bcdedit >nul
if '%errorlevel%' NEQ '0' (goto UACPrompt) else (goto UACAdmin)
:UACPrompt
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
exit /B
:UACAdmin
cd /d "%~dp0"
echo 當前運行路徑是：%CD%
echo 已獲取管理員權限
pause

到此這篇關于%1 mshta vbscript之管理員權限運行bat的解讀的文章就介紹到這了,更多相關%1 mshta vbscript內容請搜索腳本之家以前的文章或繼續(xù)瀏覽下面的相關文章希望大家以后多多支持腳本之家！

您可能感興趣的文章: