腳本之家服務器常用軟件

快捷導航

批處理系統(tǒng)管理之6?-?用戶和localgroup組篇

更新時間：2023年07月05日 23:35:59 作者：batcher

本文主要介紹?net?localgroup?命令、net?user?命令、WMIC?命令有關本地用戶和組的增刪查改等實例，以及結合BAT腳本實現(xiàn)批量操作

對于 Windows 系統(tǒng)管理員來說，經常遇到的操作可能包括：

進程
服務
注冊表
任務計劃
防火墻
網絡
用戶和組
共享
FTP

1、基本命令實例

# 創(chuàng)建本地組 BatHomeAdmins

net localgroup BatHomeAdmins /add /comment:"The group of administrators"

# 創(chuàng)建本地組 BatHomeUsers

net localgroup BatHomeUsers /add

# 添加組的描述

net localgroup BatHomeUsers /comment:"The group of users"

# 刪除組的描述

net localgroup BatHomeUsers /comment:""

# 創(chuàng)建本地用戶 BatAdmName1 密碼為 BatAdmPass1

net user BatAdmName1 BatAdmPass1 /add

# 創(chuàng)建本地用戶 BatUsrName1 密碼為 BatUsrPass1

net user BatUsrName1 BatUsrPass1 /add

# 創(chuàng)建本地用戶 BatUsrName2 密碼為 BatUsrPass2

net user BatUsrName2 BatUsrPass2 /add

# 把用戶添加到一個組

net localgroup BatHomeAdmins BatAdmName1 /add
net localgroup BatHomeUsers BatUsrName1 /add
net localgroup BatHomeUsers BatUsrName2 /add

# 查看一個組里面有哪些用戶

net localgroup BatHomeAdmins
net localgroup BatHomeUsers

# 從組里面刪除一個用戶

net localgroup BatHomeUsers BatUsrName2 /delete

# 刪除本地組

net localgroup BatHomeAdmins /delete
net localgroup BatHomeUsers /delete

# 查看一個用戶屬于哪些組

net user BatAdmName1 | findstr /i /b "本地組成員"
net user BatUsrName1 | findstr /i /b "本地組成員"

# 查看用戶列表

net users
wmic useraccount get name /value | findstr "="

# 查看某個用戶的詳細信息

net user BatAdmName1
wmic useraccount where name='BatAdmName1' get * /value

# 添加用戶的描述

net user BatAdmName1 /comment:"The administrator user"

# 刪除用戶的描述

net user BatAdmName1 /comment:""

# 設置一個用戶的全名

net user BatAdmName1 /fullname:"Guan Liyuan"

# 更改用戶的密碼

net user BatAdmName1 BatAdmPassNew

# 把用戶的密碼更改為空

net user BatAdmName1 ""

# 禁用一個用戶

net user BatAdmName1 /active:no

# 啟用一個用戶

net user BatAdmName1 /active:yes

# 設置用戶可以登錄的時間為周一到周五早九晚六

net user BatAdmName1 /time:M-F,09:00-18:00

# 設置用戶隨時可以登錄

net user BatAdmName1 /time:all

# 刪除一個用戶

net user BatUsrName2 /delete

# 獲取某個用戶的SID

wmic useraccount where name='BatUsrName1' get SID /value

# 設置某個用戶下次登錄須修改密碼

net user BatUsrName1 /logonpasswordchg:yes

# 取消某個用戶下次登錄須修改密碼

net user BatUsrName1 /logonpasswordchg:no

# 設置某個用戶的密碼永不過期

wmic useraccount where name='BatUsrName1' set PasswordExpires=false

# 設置某個用戶不能更改密碼

wmic useraccount where name='BatUsrName1' set PasswordChangeable=false

net user BatUsrName1 /passwordchg:no

# 設置某個用戶可以更改密碼

wmic useraccount where name='BatUsrName1' set PasswordChangeable=true

net user BatUsrName1 /passwordchg:yes

# 更改用戶名

wmic useraccount where name='BatUsrName1' call rename BatUsrNameNew

2、批處理腳本實例

2.1 BAT + net user 導出用戶詳細信息

@echo off
cd /d "%~dp0"
(for /f "skip=4 tokens=1-3" %%a in ('net user ^| findstr /v /i "命令成功完成。"') do (
    if "%%a" neq "" (
        net user %%a
        if "%%b" neq "" (
            net user %%b
            if "%%c" neq "" (
                net user %%c
            )
        )
    )
))&gt;"UserDetail_1.txt"

2.2 BAT + WMIC + net user 導出用戶詳細信息

@echo off
cd /d "%~dp0"
(for /f "tokens=2 delims==" %%a in ('wmic useraccount get name /value') do (
    for %%b in (%%a) do (
        net user %%b
    )
))&gt;"UserDetail_2.txt"

2.3 BAT批量創(chuàng)建用戶并加入指定組

把待創(chuàng)建的用戶名和待加入的組按照下面的格式寫入文件UserList.txt

;============================================================
;第一列: 用戶名
;第二列及后面的列: 用戶組
;每列之間以英文逗號分隔（逗號左右兩側不要有空格）
;每個組名左右兩側添加英文雙引號（不要有多余空格）
;============================================================
BatAdm1,"Administrators","Remote Desktop Users"
BatAdm2,"Remote Desktop Users"
BatUsr1,"Remote Desktop Users","Power Users"
BatUsr2,"Remote Desktop Users"

執(zhí)行腳本CreateUser.bat

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "FilePass=UserPass.txt"
&gt;"%FilePass%" echo ;Username  Password
for /f "tokens=1* delims=," %%a in ('type "UserList.txt"') do (
    call :GetPass
    &gt;&gt;"%FilePass%" echo %%a  !PassStr!
    echo net user %%a !PassStr! /add
    net user %%a !PassStr! /add
    for %%c in (%%b) do (
        echo net localgroup %%c %%a /add
        net localgroup %%c %%a /add
    )
)
pause
goto :eof
:GetPass
set "PassLen=11"
set /a LoopNum=PassLen/3+3
set "PassStr="
for /l %%i in (1,1,%LoopNum%) do (
    call :GetRand PassStr
)
set PassStr=!PassStr:~1,%PassLen%!
goto :eof
:GetRand
set "str1=ABCDEFGHIJKLMNOPQRSTUVWXYZ"
set "str2=abcdefghijklmnopqrstuvwxyz"
set "str3=0123456789"
set /a x=%random%%%26
set /a y=%random%%%26
set /a z=%random%%%10
set "PassStr=!PassStr!-!str1:~%x%,1!!str2:~%y%,1!!str3:~%z%,1!"
goto :eof

創(chuàng)建用戶之后隨機生成的密碼自動寫入UserPass.txt