欧美bbbwbbbw肥妇,免费乱码人妻系列日韩,一级黄片

把數(shù)據(jù)存儲(chǔ)到 XML 文件

通常，我們?cè)跀?shù)據(jù)庫中存儲(chǔ)數(shù)據(jù)。不過，如果希望數(shù)據(jù)的可移植性更強(qiáng)，我們可以把數(shù)據(jù)存儲(chǔ) XML 文件中。

創(chuàng)建并保存 XML 文件

如果數(shù)據(jù)要被傳送到非 Windows 平臺(tái)上的應(yīng)用程序，那么把數(shù)據(jù)保存在 XML 文件中是有好處的。請(qǐng)記住，XML 有很強(qiáng)的跨平臺(tái)可移植性，并且數(shù)據(jù)無需轉(zhuǎn)換！

首先，我們將學(xué)習(xí)如何創(chuàng)建并保存一個(gè) XML 文件。下面的這個(gè) XML 文件將被命名為 "test.xml"，并被保存在服務(wù)器上的 c 目錄中。我們將使用 ASP 和微軟的 XMLDOM 對(duì)象來創(chuàng)建并保存這個(gè) XML 文件：

<%
Dim xmlDoc, rootEl, child1, child2, p

'創(chuàng)建XML文檔
Set xmlDoc = Server.CreateObject("Microsoft.XMLDOM")

'創(chuàng)建根元素并將之加入文檔
Set rootEl = xmlDoc.createElement("root")
xmlDoc.appendChild rootEl

'創(chuàng)建并加入子元素
Set child1 = xmlDoc.createElement("child1")
Set child2 = xmlDoc.createElement("child2")
rootEl.appendChild child1
rootEl.appendChild child2

'創(chuàng)建 XML processing instruction
'并把它加到根元素之前
Set p=xmlDoc.createProcessingInstruction("xml","version='1.0'")
xmlDoc.insertBefore p,xmlDoc.childNodes(0)

'把文件保存到 C 目錄
xmlDoc.Save "c:\test.xml"
%>

如果您打開這個(gè)被保存的文件，它會(huì)使這個(gè)樣子 ("test.xml")：

<?xml version="1.0"?>
<root>
  <child1 />
  <child2 />
</root>

真實(shí)的表單例子

現(xiàn)在，我們看一個(gè)真實(shí)的表單例子。

我們首先看一下這個(gè)被用在例子中的 HTML 表單：下面的HTML表單要求用戶輸入他們的名字、國籍以及電子郵件地址。隨后這些信息會(huì)被寫到一個(gè) XML 文件，以便存儲(chǔ)。

"customers.htm":

<html>

<body>
<form action="saveForm.asp" method="post">
<h1>請(qǐng)輸入您的聯(lián)系信息：</h1>
<label>名字: </label>
<p><input type="text" id="firstName" name="firstName"></p>

<label>姓氏: </label>
<p><input type="text" id="lastName" name="lastName"></p>

<label>國家: </label>
<p><input type="text" id="country" name="country"></p>

<label>郵件: </label>
<p><input type="text" id="email" name="email"></p>

<p>
<input type="submit" id="btn_sub" name="btn_sub" value="Submit">
<input type="reset" id="btn_res" name="btn_res" value="Reset">
</p>
</form>
</body>

</html>

用于以上 HTML 表單的 action 被設(shè)置為 "saveForm.asp"。"saveForm.asp" 文件是一個(gè) ASP 頁面，可循環(huán)遍表單域，并把它們的值存儲(chǔ)在一個(gè) XML 文件中：

<%
dim xmlDoc
dim rootEl,fieldName,fieldValue,attID
dim p,i

'如果有錯(cuò)誤發(fā)生，不允許程序終止
On Error Resume Next

Set xmlDoc = server.CreateObject("Microsoft.XMLDOM")
xmlDoc.preserveWhiteSpace=true

'創(chuàng)建并向文檔添加根元素
Set rootEl = xmlDoc.createElement("customer")
xmlDoc.appendChild rootEl

'循環(huán)遍歷 Form 集
for i = 1 To Request.Form.Count
  '除去表單中的 button 元素
  if instr(1,Request.Form.Key(i),"btn_")=0 then
    '創(chuàng)建 field 和 value 元素，以及 id 屬性
    Set fieldName = xmlDoc.createElement("field")
    Set fieldValue = xmlDoc.createElement("value")
    Set attID = xmlDoc.createAttribute("id")
    '把當(dāng)前表單域的名稱設(shè)置為 id 屬性的值
    attID.Text = Request.Form.Key(i)
    '把 id 屬性添加到 field 元素
    fieldName.setAttributeNode attID
    '把當(dāng)前表單域的值設(shè)置為 value 元素的值
    fieldValue.Text = Request.Form(i)
    '將 field 元素作為根元素的子元素進(jìn)行添加
    rootEl.appendChild fieldName
    '將 value 元素作為 field 元素的子元素進(jìn)行添加
    fieldName.appendChild fieldValue
  end if
next

'添加 XML processing instruction
'并把它加到根元素之前
Set p = xmlDoc.createProcessingInstruction("xml","version='1.0'")
xmlDoc.insertBefore p,xmlDoc.childNodes(0)

'保存 XML 文件
xmlDoc.save "c:\Customer.xml"

'釋放所有的對(duì)象引用
set xmlDoc=nothing
set rootEl=nothing
set fieldName=nothing
set fieldValue=nothing
set attID=nothing
set p=nothing

'測試是否有錯(cuò)誤發(fā)生
if err.number<>0 then
  response.write("Error: No information saved.")
else
  response.write("Your information has been saved.")
end if
%>

注釋：如果指定的 XML 文件名已經(jīng)存在，那個(gè)文件會(huì)被覆蓋！

XML 文件會(huì)由上面的代碼生成，大致的樣子是這樣的：("Customer.xml"):

<?xml version="1.0" ?>
<customer>
  <field id="firstName">
    <value>David</value> 
  </field>
  <field id="lastName">
    <value>Smith</value> 
  </field>
  <field id="country">
    <value>China</value> 
  </field>
  <field id="email">
    <value>mymail@myaddress.com</value> 
  </field>
</customer>