快捷導(dǎo)航

Transpose 數(shù)組行列轉(zhuǎn)置的限制方式

更新時(shí)間：2020年02月11日 13:05:01 投稿：jingxian

今天小編就為大家分享一篇Transpose 數(shù)組行列轉(zhuǎn)置的限制方式，具有很好的參考價(jià)值，希望對(duì)大家有所幫助。一起跟隨小編過(guò)來(lái)看看吧

提到數(shù)組，大家都不陌生，什么是數(shù)組行列轉(zhuǎn)置呢？其實(shí)也很簡(jiǎn)單，如下圖所示，行列轉(zhuǎn)置就是將數(shù)組元素的存放方式進(jìn)行轉(zhuǎn)換，原來(lái)保存在第一列的數(shù)據(jù)，將保持在新數(shù)組的第一行，并且保持原有順序，即6在第一個(gè)位置，8在最后一個(gè)位置。其他列依次類推。

在Excel工作表中有個(gè)強(qiáng)大的函數(shù)Transpose，可以直接實(shí)現(xiàn)數(shù)組行列轉(zhuǎn)置，作為VBA開(kāi)發(fā)者來(lái)說(shuō)，肯定不會(huì)忘記用這個(gè)。

Sub Demo1()
  Dim aData(1 To 3, 1 To 2)
  For i = 1 To 3
    For j = 1 To 2
      aData(i, j) = i + j * 5
    Next j
  Next i
  aTrans = Application.Transpose(aData)
  Debug.Print UBound(aData, 1) & " x "; UBound(aData, 2)
  Debug.Print "=>>"
  Debug.Print UBound(aTrans, 1) & " x "; UBound(aTrans, 2)
End Sub

一句代碼輕松實(shí)現(xiàn)轉(zhuǎn)置，比很多程序開(kāi)發(fā)語(yǔ)言都要簡(jiǎn)單，在本地窗口中可以看到轉(zhuǎn)置效果。

這么好用的神奇代碼，有時(shí)會(huì)莫名其妙的罷工，我們來(lái)看看下面的代碼，運(yùn)行代碼將給出“類型不匹配”的錯(cuò)誤提示，錯(cuò)誤號(hào)為“13”。

Sub Demo2()
  Dim aData(1 To 3, 1 To 2)
  For i = 1 To 3
    For j = 1 To 2
      aData(i, j) = i + j * 5
    Next j
  Next i
  aData(1, 1) = Application.Rept("$", 256)
  aTrans = Application.Transpose(aData)  ' Runtime error "13"
  Debug.Print UBound(aData, 1) & " x "; UBound(aData, 2)
  Debug.Print "=>>"
  Debug.Print UBound(aTrans, 1) & " x "; UBound(aTrans, 2)
End Sub

轉(zhuǎn)置失敗的原因在于aData(1,1)的字符長(zhǎng)度為256，Transpose所能夠處理的數(shù)組元素字符長(zhǎng)度最大為255。有時(shí)就是需要處理這樣的數(shù)組元素，那么我們可以使用自定義函數(shù)進(jìn)行數(shù)組的行列轉(zhuǎn)置。TrasnposeArray可以實(shí)現(xiàn)二維數(shù)組的行列轉(zhuǎn)置。其效果與Transpose函數(shù)相同。

Sub Demo3()
  Dim aData(1 To 3, 1 To 2)
  For i = 1 To 3
    For j = 1 To 2
      aData(i, j) = i + j * 5
    Next j
  Next i
  aData(1, 1) = Application.Rept("$", 256)
  aTrans = TransposeArray(aData)
  Debug.Print UBound(aData, 1) & " x "; UBound(aData, 2)
  Debug.Print "=>>"
  Debug.Print UBound(aTrans, 1) & " x "; UBound(aTrans, 2)
End Sub
 
Function TransposeArray(arrA) As Variant
  Dim aRes()
  If VBA.IsArray(arrA) Then
    ReDim aRes(LBound(arrA, 2) To UBound(arrA, 2), LBound(arrA, 1) To UBound(arrA, 1))
    For i = LBound(arrA, 1) To UBound(arrA, 1)
      For j = LBound(arrA, 2) To UBound(arrA, 2)
        aRes(j, i) = arrA(i, j)
      Next
    Next
    TransposeArray = aRes
  End If
End Function

補(bǔ)充說(shuō)明一點(diǎn)，由于Transpose本身是工作表函數(shù)，因此大家使用時(shí)，需要注意它的另一個(gè)限制，就是被轉(zhuǎn)置數(shù)組的最大行數(shù)是65,536。

以上這篇Transpose 數(shù)組行列轉(zhuǎn)置的限制方式就是小編分享給大家的全部?jī)?nèi)容了，希望能給大家一個(gè)參考，也希望大家多多支持腳本之家。

您可能感興趣的文章: