問題求助SOS：如何對(duì)比兩個(gè)單元格字符，將交叉重復(fù)的字符提取到另一個(gè)單元格中？

雖然小編不知道這位朋友咨詢的問題具體應(yīng)用于什么辦公場(chǎng)景中，但既然提出了問題，肯定就是存在具體的需求，那咱就要想方法解決一下。

微軟Office LTSC 2021專業(yè)增強(qiáng)版 簡(jiǎn)體中文批量許可版 2024年09月更新

• 類型：辦公軟件
• 大?。?/span>2.2GB
• 語(yǔ)言：簡(jiǎn)體中文
• 時(shí)間：2024-09-12

查看詳情

WPS Office 2025 V12.1.0.21915 官方最新正式版

• 類型：辦公軟件
• 大?。?/span>260MB
• 語(yǔ)言：簡(jiǎn)體中文
• 時(shí)間：2025-07-03

查看詳情

如下圖所示：

有“數(shù)據(jù)A”與“數(shù)據(jù)B”兩列數(shù)據(jù)，我們想要把每行對(duì)應(yīng)的兩個(gè)單元格中的重復(fù)出現(xiàn)的字符提取到C列單元格中顯示。

比如A2與B2單元格中都存在“1”與“4”，故在C2單元格中顯示交叉重復(fù)值：“14”。

舉例數(shù)據(jù)清晰明了，提干相對(duì)簡(jiǎn)單。

下面我們分兩種思路進(jìn)行問題剖析，兩種方法都用到了REGEXP正則表達(dá)式函數(shù)（WPS版），可見學(xué)習(xí)并了解一些REGEXP函數(shù)的常規(guī)知識(shí)很重要。

第一步：正則字符拆分

輸入強(qiáng)大的REGEXP正則表達(dá)式函數(shù)：

=REGEXP(B2,".")

.（點(diǎn)）：表示任意的單個(gè)字符。

REGEXP函數(shù)省略第3參數(shù)，表示“提取”模式。提取B2單元格中任意的單個(gè)字符，則會(huì)把所有的單個(gè)字符以數(shù)組溢出的方式顯示在一行多個(gè)單元格中。

此步的核心目的：

按1個(gè)字符的長(zhǎng)度進(jìn)行數(shù)據(jù)分列。

第二步：正則二次提取

繼續(xù)向外嵌套一個(gè)REGEXP函數(shù)：

=REGEXP(A2,REGEXP(B2,"."),0)

我們將上一步REGEXP提取到B2單元格的每個(gè)字符在A2單元格內(nèi)容中進(jìn)行查找，如果出現(xiàn)過，則被提取顯示出來；沒有出現(xiàn)過的，則顯示成錯(cuò)誤值。

比如B2單元格中的字符“1”與“4”，在A2單元格“12345”內(nèi)容中出現(xiàn)過，故顯示為“1”與“4”，而B2單元格中的字符“7”與“8”與“9”，在A2單元格“12345”內(nèi)容中未出現(xiàn)過，故顯示為錯(cuò)誤值。

原理很容易理解。

第三步：規(guī)避錯(cuò)誤值

使用常見的規(guī)避錯(cuò)誤值函數(shù)IFERROR函數(shù)：

=IFERROR(REGEXP(A2,REGEXP(B2,"."),0),"")

將上一步的公式，作為IFERROR函數(shù)的第一參數(shù)判斷條件，如果第一參數(shù)返回錯(cuò)誤值，則強(qiáng)制執(zhí)行顯示為第二參數(shù)空值；否則返回第一參數(shù)本身。

第四步：合并

使用常規(guī)的CONCAT合并類函數(shù)：

=CONCAT(IFERROR(REGEXP(A2,REGEXP(B2,"."),0),""))

將上一步提取到的、散落在不同單元格的“交叉重復(fù)值”，合并到一個(gè)單元格中顯示。

如果想用間隔符進(jìn)行間隔的話，可以用TEXTJOIN函數(shù)代替CONCAT函數(shù)。

下面我們繼續(xù)說說第二種解題思路。

第一步：正則字符拆分

使用REGEXP函數(shù)：

=REGEXP(B2,".")

與第一種方法的第一步原理完全相同。核心目的：按1個(gè)字符的長(zhǎng)度進(jìn)行數(shù)據(jù)分列。

第二步：查找

使用FIND查找函數(shù)：

=FIND(REGEXP(B2,"."),A2)

查找B2單元格中的每個(gè)字符，依次在A2單元格中出現(xiàn)的起始位置。

比如B2單元格中的“1”與“4”在A2單元格中的起始位置依次是第1個(gè)位置與第4個(gè)位置，故返回“1”與“4”；而“7”、“8”、“9”在A2單元格中均未出現(xiàn)過，所以查找不到對(duì)應(yīng)的位置，顯示錯(cuò)誤值。

第三步：提取

使用MID提取類函數(shù)：

=MID(A2,FIND(REGEXP(B2,"."),A2),1)

以A2、B2單元格為例：

在A2單元格內(nèi)，分別從第1個(gè)起始位置處、第4個(gè)起始位置處，提取字符長(zhǎng)度為1的字符串，故返回“1”與“4”。

第四步：規(guī)避錯(cuò)誤值

使用IFERROR函數(shù)：

=IFERROR(MID(A2,FIND(REGEXP(B2,"."),A2),1),"")

如果第一參數(shù)（上一步公式返回結(jié)果）為錯(cuò)誤值，則顯示為第二參數(shù)指定的固定值空值。否則返回第一參數(shù)本身。

第五步：合并

使用CONCAT合并類函數(shù)：

=CONCAT(IFERROR(MID(A2,FIND(REGEXP(B2,"."),A2),1),""))

將上一步返回的“交叉重復(fù)值”合并到一個(gè)單元格中顯示。

推薦閱讀：實(shí)現(xiàn)動(dòng)態(tài)裝箱計(jì)算! wps中ddb+text函數(shù)公式的使用技巧

最新評(píng)論